[arch-commits] Commit in elvish/repos/community-x86_64 (4 files)

[George Rawlinson]

    Date: Monday, March 21, 2022 @ 06:59:16
  Author: grawlinson
Revision: 1166652

archrelease: copy trunk to community-x86_64

Added:
  elvish/repos/community-x86_64/PKGBUILD
    (from rev 1166651, elvish/trunk/PKGBUILD)
  elvish/repos/community-x86_64/elvish.install
    (from rev 1166651, elvish/trunk/elvish.install)
Deleted:
  elvish/repos/community-x86_64/PKGBUILD
  elvish/repos/community-x86_64/elvish.install

----------------+
 PKGBUILD       |  137 ++++++++++++++++++++++++++++---------------------------
 elvish.install |   28 +++++------
 2 files changed, 86 insertions(+), 79 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2022-03-21 06:58:11 UTC (rev 1166651)
+++ PKGBUILD	2022-03-21 06:59:16 UTC (rev 1166652)
@@ -1,65 +0,0 @@
-# Maintainer: George Rawlinson <grawlinson at archlinux.org>
-# Contributor: Haochen Tong <i at hexchain dot org>
-# Contributor: Qi Xiao <xiaqqaix at gmail dot com>
-
-pkgname=elvish
-pkgver=0.17.0
-pkgrel=1
-pkgdesc="A friendly and expressive Unix shell"
-arch=('x86_64')
-url="https://elv.sh"
-license=('BSD')
-depends=('glibc')
-makedepends=('git' 'go')
-install="$pkgname.install"
-source=("$pkgname-$pkgver.tar.gz::https://github.com/elves/elvish/archive/v$pkgver.tar.gz")
-sha512sums=('bbf4895a99f3c1aa1d35cc04073feba121fda72afcb5dc241c5b1ded3c3f815d81f3ad4b9a51878ead865ecee3ea5dacc855a38057aa7e49a2ada306fc950895')
-b2sums=('3725787f287dff6d2e740f75a4a62a47815166c7146d32b9358720209fc9eb4660b68599f8cc05313a44a5f02d97a0b30077588d9950048ae02a66f741795096')
-
-prepare() {
-  cd "$pkgname-$pkgver"
-
-  # create directory for build output
-  mkdir build
-
-  # download dependencies
-  go mod download
-}
-
-build() {
-  cd "$pkgname-$pkgver"
-
-  # set Go flags
-  export CGO_CPPFLAGS="${CPPFLAGS}"
-  export CGO_CFLAGS="${CFLAGS}"
-  export CGO_CXXFLAGS="${CXXFLAGS}"
-
-  go build -v \
-    -trimpath \
-    -buildmode=pie \
-    -mod=readonly \
-    -modcacherw \
-    -ldflags "-linkmode external -extldflags ${LDFLAGS} \
-    -X github.com/elves/elvish/pkg/buildinfo.Reproducible=true \
-    -X github.com/elves/elvish/pkg/buildinfo.Version=$pkgver" \
-    -o build \
-    ./cmd/...
-}
-
-check() {
-  cd "$pkgname-$pkgver"
-  go test -v -race ./...
-}
-
-package() {
-  cd "$pkgname-$pkgver"
-
-  # binary
-  install -vDm755 -t "$pkgdir/usr/bin" build/elvish
-
-  # documentation
-  install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" ./*.md
-
-  # license
-  install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
-}

Copied: elvish/repos/community-x86_64/PKGBUILD (from rev 1166651, elvish/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2022-03-21 06:59:16 UTC (rev 1166652)
@@ -0,0 +1,72 @@
+# Maintainer: George Rawlinson <grawlinson at archlinux.org>
+# Contributor: Haochen Tong <i at hexchain dot org>
+# Contributor: Qi Xiao <xiaqqaix at gmail dot com>
+
+pkgname=elvish
+pkgver=0.18.0
+pkgrel=1
+pkgdesc="A friendly and expressive Unix shell"
+arch=('x86_64')
+url="https://elv.sh"
+license=('BSD')
+depends=('glibc')
+makedepends=('git' 'go')
+install="$pkgname.install"
+options=('!lto')
+_commit='214665f014b7d2e6e2d17ee33e9057bab323f842'
+source=("$pkgname::git+https://github.com/elves/elvish.git#commit=$_commit")
+b2sums=('SKIP')
+
+pkgver() {
+  cd "$pkgname"
+
+  git describe --tags | sed 's/^v//'
+}
+
+prepare() {
+  cd "$pkgname"
+
+  # create directory for build output
+  mkdir build
+
+  # download dependencies
+  go mod download
+}
+
+build() {
+  cd "$pkgname"
+
+  # set Go flags
+  export CGO_CPPFLAGS="${CPPFLAGS}"
+  export CGO_CFLAGS="${CFLAGS}"
+  export CGO_CXXFLAGS="${CXXFLAGS}"
+
+  go build -v \
+    -trimpath \
+    -buildmode=pie \
+    -mod=readonly \
+    -modcacherw \
+    -ldflags "-linkmode external -extldflags ${LDFLAGS} \
+    -X github.com/elves/elvish/pkg/buildinfo.Reproducible=true \
+    -X github.com/elves/elvish/pkg/buildinfo.Version=$pkgver" \
+    -o build \
+    ./cmd/...
+}
+
+check() {
+  cd "$pkgname"
+  go test -v -race ./...
+}
+
+package() {
+  cd "$pkgname"
+
+  # binary
+  install -vDm755 -t "$pkgdir/usr/bin" build/elvish
+
+  # documentation
+  install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" ./*.md
+
+  # license
+  install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
+}

Deleted: elvish.install
===================================================================
--- elvish.install	2022-03-21 06:58:11 UTC (rev 1166651)
+++ elvish.install	2022-03-21 06:59:16 UTC (rev 1166652)
@@ -1,14 +0,0 @@
-post_install() {
-  grep -Fqx /bin/elvish /etc/shells || echo /bin/elvish >> /etc/shells
-  grep -Fqx /usr/bin/elvish /etc/shells || echo /usr/bin/elvish >> /etc/shells
-}
-
-post_upgrade() {
-  post_install
-}
-
-pre_remove() {
-  sed -i -r '/^(\/usr)?\/bin\/elvish$/d' etc/shells
-}
-
-# vim:set ts=2 sw=2 et:

Copied: elvish/repos/community-x86_64/elvish.install (from rev 1166651, elvish/trunk/elvish.install)
===================================================================
--- elvish.install	                        (rev 0)
+++ elvish.install	2022-03-21 06:59:16 UTC (rev 1166652)
@@ -0,0 +1,14 @@
+post_install() {
+  grep -Fqx /bin/elvish /etc/shells || echo /bin/elvish >> /etc/shells
+  grep -Fqx /usr/bin/elvish /etc/shells || echo /usr/bin/elvish >> /etc/shells
+}
+
+post_upgrade() {
+  post_install
+}
+
+pre_remove() {
+  sed -i -r '/^(\/usr)?\/bin\/elvish$/d' etc/shells
+}
+
+# vim:set ts=2 sw=2 et: