[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Monday, March 21, 2022 @ 13:41:42
  Author: felixonmars
Revision: 1166860

addpkg: haskell-pandoc-lua-marshal 0.1.3.1-1

Added:
  haskell-pandoc-lua-marshal/
  haskell-pandoc-lua-marshal/repos/
  haskell-pandoc-lua-marshal/trunk/
  haskell-pandoc-lua-marshal/trunk/PKGBUILD

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Added: haskell-pandoc-lua-marshal/trunk/PKGBUILD
===================================================================
--- haskell-pandoc-lua-marshal/trunk/PKGBUILD	                        (rev 0)
+++ haskell-pandoc-lua-marshal/trunk/PKGBUILD	2022-03-21 13:41:42 UTC (rev 1166860)
@@ -0,0 +1,52 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=pandoc-lua-marshal
+pkgname=haskell-pandoc-lua-marshal
+pkgver=0.1.3.1
+pkgrel=1
+pkgdesc="Use pandoc types in Lua"
+url="https://github.com/pandoc/pandoc-lua-marshal"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-hslua' 'haskell-hslua-marshalling' 'haskell-lua' 'haskell-pandoc-types'
+         'haskell-safe')
+makedepends=('ghc' 'uusi' 'haskell-quickcheck' 'haskell-tasty' 'haskell-tasty-hunit'
+             'haskell-tasty-lua' 'haskell-tasty-quickcheck')
+source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz")
+sha256sums=('31a297410f90a9f7266520b5b00c0a1d2a7af6f6509afe84f7cd4f7cdf180413')
+
+prepare() {
+  cd $_hkgname-$pkgver
+  gen-setup
+}
+
+build() {
+  cd $_hkgname-$pkgver
+
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+    --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
+    --ghc-option='-pie'
+
+  runhaskell Setup build
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd $_hkgname-$pkgver
+  runhaskell Setup test
+}
+
+package() {
+  cd $_hkgname-$pkgver
+
+  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -D -m644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
+  rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}