[arch-commits] Commit in mutter/repos/extra-x86_64 (PKGBUILD PKGBUILD)

[Jan Steffens]

    Date: Tuesday, March 22, 2022 @ 01:46:57
  Author: heftig
Revision: 440513

archrelease: copy trunk to extra-x86_64

Added:
  mutter/repos/extra-x86_64/PKGBUILD
    (from rev 440511, mutter/trunk/PKGBUILD)
Deleted:
  mutter/repos/extra-x86_64/PKGBUILD

----------+
 PKGBUILD |  147 ++++++++++++++++++++++++++++++-------------------------------
 1 file changed, 74 insertions(+), 73 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2022-03-22 01:46:56 UTC (rev 440512)
+++ PKGBUILD	2022-03-22 01:46:57 UTC (rev 440513)
@@ -1,73 +0,0 @@
-# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
-# Contributor: Ionut Biru <ibiru at archlinux.org>
-# Contributor: Michael Kanis <mkanis_at_gmx_dot_de>
-
-pkgname=mutter
-pkgver=41.4
-pkgrel=1
-pkgdesc="A window manager for GNOME"
-url="https://gitlab.gnome.org/GNOME/mutter"
-arch=(x86_64)
-license=(GPL)
-depends=(dconf gobject-introspection-runtime gsettings-desktop-schemas
-         libcanberra startup-notification zenity libsm gnome-desktop upower
-         libxkbcommon-x11 gnome-settings-daemon libgudev libinput pipewire
-         xorg-xwayland graphene libxkbfile libsysprof-capture)
-makedepends=(gobject-introspection git egl-wayland meson xorg-server
-             wayland-protocols sysprof)
-checkdepends=(xorg-server-xvfb pipewire-media-session python-dbusmock)
-provides=(libmutter-9.so)
-groups=(gnome)
-_commit=83a34957046c5b6bca609fda4b68c8c5d1276d14  # tags/41.4^0
-source=("git+https://gitlab.gnome.org/GNOME/mutter.git#commit=$_commit")
-sha256sums=('SKIP')
-
-pkgver() {
-  cd mutter
-  git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
-}
-
-prepare() {
-  cd mutter
-
-  # Make tests run
-  sed -i '/catchsegv/d' meson.build
-}
-
-build() {
-  CFLAGS="${CFLAGS/-O2/-O3} -fno-semantic-interposition"
-  LDFLAGS+=" -Wl,-Bsymbolic-functions"
-
-  arch-meson mutter build \
-    -D egl_device=true \
-    -D wayland_eglstream=true \
-    -D installed_tests=false
-  meson compile -C build
-}
-
-_check() (
-  mkdir -p -m 700 "${XDG_RUNTIME_DIR:=$PWD/runtime-dir}"
-  glib-compile-schemas "${GSETTINGS_SCHEMA_DIR:=$PWD/build/data}"
-  export XDG_RUNTIME_DIR GSETTINGS_SCHEMA_DIR
-
-  pipewire &
-  _p1=$!
-
-  pipewire-media-session &
-  _p2=$!
-
-  trap "kill $_p1 $_p2; wait" EXIT
-
-  meson test -C build --print-errorlogs
-)
-
-check() {
-  dbus-run-session xvfb-run -s '-nolisten local +iglx -noreset' \
-    bash -c "$(declare -f _check); _check"
-}
-
-package() {
-  meson install -C build --destdir "$pkgdir"
-}
-
-# vim:set sw=2 et:

Copied: mutter/repos/extra-x86_64/PKGBUILD (from rev 440511, mutter/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2022-03-22 01:46:57 UTC (rev 440513)
@@ -0,0 +1,74 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Ionut Biru <ibiru at archlinux.org>
+# Contributor: Michael Kanis <mkanis_at_gmx_dot_de>
+
+pkgname=mutter
+pkgver=41.5
+pkgrel=1
+pkgdesc="A window manager for GNOME"
+url="https://gitlab.gnome.org/GNOME/mutter"
+arch=(x86_64)
+license=(GPL)
+depends=(dconf gobject-introspection-runtime gsettings-desktop-schemas
+         libcanberra startup-notification zenity libsm gnome-desktop upower
+         libxkbcommon-x11 gnome-settings-daemon libgudev libinput pipewire
+         xorg-xwayland graphene libxkbfile libsysprof-capture)
+makedepends=(gobject-introspection git egl-wayland meson xorg-server
+             wayland-protocols sysprof)
+checkdepends=(xorg-server-xvfb pipewire-media-session python-dbusmock)
+provides=(libmutter-9.so)
+groups=(gnome)
+options=(debug)
+_commit=17926e941d67867911c462737f4d013adb55e4d6  # tags/41.5^0
+source=("git+https://gitlab.gnome.org/GNOME/mutter.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd mutter
+  git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
+}
+
+prepare() {
+  cd mutter
+
+  # Make tests run
+  sed -i '/catchsegv/d' meson.build
+}
+
+build() {
+  CFLAGS="${CFLAGS/-O2/-O3} -fno-semantic-interposition"
+  LDFLAGS+=" -Wl,-Bsymbolic-functions"
+
+  arch-meson mutter build \
+    -D egl_device=true \
+    -D wayland_eglstream=true \
+    -D installed_tests=false
+  meson compile -C build
+}
+
+_check() (
+  mkdir -p -m 700 "${XDG_RUNTIME_DIR:=$PWD/runtime-dir}"
+  glib-compile-schemas "${GSETTINGS_SCHEMA_DIR:=$PWD/build/data}"
+  export XDG_RUNTIME_DIR GSETTINGS_SCHEMA_DIR
+
+  pipewire &
+  _p1=$!
+
+  pipewire-media-session &
+  _p2=$!
+
+  trap "kill $_p1 $_p2; wait" EXIT
+
+  meson test -C build --print-errorlogs
+)
+
+check() {
+  dbus-run-session xvfb-run -s '-nolisten local +iglx -noreset' \
+    bash -c "$(declare -f _check); _check"
+}
+
+package() {
+  meson install -C build --destdir "$pkgdir"
+}
+
+# vim:set sw=2 et: