[arch-commits] Commit in libepoxy/trunk (PKGBUILD)
Jan Steffens
heftig at gemini.archlinux.org
Tue Mar 22 00:35:01 UTC 2022
Date: Tuesday, March 22, 2022 @ 00:35:00
Author: heftig
Revision: 440465
1.5.10-1
Modified:
libepoxy/trunk/PKGBUILD
----------+
PKGBUILD | 32 +++++++++++++++++++++++++-------
1 file changed, 25 insertions(+), 7 deletions(-)
Modified: PKGBUILD
===================================================================
--- PKGBUILD 2022-03-22 00:26:33 UTC (rev 440464)
+++ PKGBUILD 2022-03-22 00:35:00 UTC (rev 440465)
@@ -1,6 +1,8 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
# Maintainer: Laurent Carlier <lordheavym at gmail.com>
-pkgname=libepoxy
+pkgbase=libepoxy
+pkgname=(libepoxy libepoxy-docs)
pkgver=1.5.10
pkgrel=1
pkgdesc="Library handling OpenGL function pointer management"
@@ -8,24 +10,25 @@
arch=(x86_64)
license=(MIT)
depends=(glibc)
-makedepends=(python mesa-libgl git meson doxygen graphviz)
+makedepends=(git meson mesa-libgl systemd doxygen graphviz)
checkdepends=(xorg-server-xvfb)
options=(debug)
_commit=c84bc9459357a40e46e2fec0408d04fbdde2c973 # tags/1.5.10^0
source=("git+https://github.com/anholt/libepoxy#commit=$_commit")
sha256sums=('SKIP')
+validpgpkeys=('53EF3DC3B63E2899271BD26322E8091EEA11BBB7') # Emmanuele Bassi <ebassi at gnome.org>
pkgver() {
- cd $pkgname
+ cd libepoxy
git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
}
prepare() {
- cd $pkgname
+ cd libepoxy
}
build() {
- arch-meson $pkgname build -D docs=true
+ arch-meson libepoxy build -D docs=true
meson compile -C build
}
@@ -34,9 +37,24 @@
meson test -C build --print-errorlogs
}
-package() {
+package_libepoxy() {
+ provides=(libepoxy.so)
+
meson install -C build --destdir "$pkgdir"
- install -Dm644 $pkgname/COPYING "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+
+ mkdir -p doc/usr/share
+ mv {"$pkgdir",doc}/usr/share/doc
+
+ install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 libepoxy/COPYING
}
+package_libepoxy-docs() {
+ pkgdesc+=" (documentation)"
+ depends=()
+
+ mv doc/* "$pkgdir"
+
+ install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 libepoxy/COPYING
+}
+
# vim:set sw=2 et:
More information about the arch-commits
mailing list