[arch-commits] Commit in luasocket/repos (2 files)

[Caleb Maclennan]

    Date: Friday, March 25, 2022 @ 09:59:52
  Author: alerque
Revision: 1176185

archrelease: copy trunk to community-testing-x86_64

Added:
  luasocket/repos/community-testing-x86_64/
  luasocket/repos/community-testing-x86_64/PKGBUILD
    (from rev 1176184, luasocket/trunk/PKGBUILD)

----------+
 PKGBUILD |   59 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)

Copied: luasocket/repos/community-testing-x86_64/PKGBUILD (from rev 1176184, luasocket/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2022-03-25 09:59:52 UTC (rev 1176185)
@@ -0,0 +1,59 @@
+# Maintainer: Sergej Pupykin <pupykin.s+arch at gmail.com>
+# Maintainer: Caleb Maclennana <caleb at alerque.com>
+# Contributor: Anders Bergh <anders1 at gmail.com>
+
+pkgbase=luasocket
+pkgname=(lua-socket lua51-socket lua52-socket lua53-socket)
+pkgver=3.0.0
+pkgrel=1
+_rockrel=1
+epoch=1
+pkgdesc='Networking support library for the Lua language'
+arch=(x86_64)
+url="https://github.com/lunarmodules/$pkgbase"
+license=(MIT)
+options=(debug)
+makedepends=(lua
+             lua51
+             lua52
+             lua53
+             luarocks)
+_archive="$pkgbase-$pkgver"
+_rock="$_archive-$_rockrel.linux-$CARCH.rock"
+source=("$url/archive/v$pkgver/$_archive.tar.gz")
+sha256sums=('04d98e40edcee7c7c5f83f0e8ba5503d14b56280e20daceee9e34ed7cf8f1b15')
+
+build() {
+	cd "$_archive"
+	for LUAVER in 5.1 5.2 5.3 5.4; do
+		luarocks --lua-version "$LUAVER" \
+			make --pack-binary-rock --deps-mode none -- "rockspecs/$_archive-$_rockrel.rockspec"
+		install -Dm0644 -t "lua$LUAVER/" "$_rock"
+	done
+}
+
+_package() {
+	cd "$_archive"
+	depends=("${pkgname%-*}")
+	luarocks --lua-version "$1" --tree "$pkgdir/usr/" \
+		install --deps-mode none --no-manifest -- "lua$1/$_rock"
+	install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname/" LICENSE
+}
+
+package_lua-socket() {
+	_package 5.4
+}
+
+package_lua53-socket() {
+	_package 5.3
+}
+
+package_lua52-socket() {
+	_package 5.2
+}
+
+package_lua51-socket() {
+	replaces=(luasocket)
+	conflicts=(luasocket)
+	_package 5.1
+}