[arch-commits] Commit in (4 files)

[Evangelos Foutras]

    Date: Friday, March 25, 2022 @ 13:39:20
  Author: foutrelis
Revision: 1176374

Add libmemcached-awesome replacing libmemcached

Added:
  libmemcached-awesome/
  libmemcached-awesome/repos/
  libmemcached-awesome/trunk/
  libmemcached-awesome/trunk/PKGBUILD

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Added: libmemcached-awesome/trunk/PKGBUILD
===================================================================
--- libmemcached-awesome/trunk/PKGBUILD	                        (rev 0)
+++ libmemcached-awesome/trunk/PKGBUILD	2022-03-25 13:39:20 UTC (rev 1176374)
@@ -0,0 +1,44 @@
+# Maintainer: Evangelos Foutras <evangelos at foutrelis.com>
+
+pkgname=libmemcached-awesome
+pkgver=1.1.1
+pkgrel=1
+pkgdesc="C/C++ client library and tools for the memcached server"
+arch=('x86_64')
+url="https://awesomized.github.io/libmemcached/"
+license=('BSD')
+depends=('gcc-libs' 'libsasl' 'libevent')
+makedepends=('cmake' 'memcached' 'python-sphinx' 'python-sphinx_rtd_theme')
+provides=('libmemcached')
+conflicts=('libmemcached')
+replaces=('libmemcached')
+source=(https://github.com/awesomized/libmemcached/archive/$pkgver/$pkgname-$pkgver.tar.gz)
+sha256sums=('6e135edc66b7763fc6aa30fe0175fc9b12309e915f41e0849ae5225c7c954f19')
+
+build() {
+  cmake -B build -S libmemcached-$pkgver \
+    -DCMAKE_BUILD_TYPE=None \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DBUILD_DOCS=ON \
+    -DBUILD_DOCS_MANGZ=OFF \
+    -DBUILD_TESTING=ON \
+    -DENABLE_SASL=ON \
+    -DENABLE_HASH_HSIEH=ON \
+    -DENABLE_HASH_FNV64=ON \
+    -DENABLE_HASH_MURMUR=ON \
+    -DENABLE_MEMASLAP=ON \
+    -DENABLE_OPENSSL_CRYPTO=ON
+  cmake --build build
+}
+
+check() {
+  cd build
+  ctest --output-on-failure
+}
+
+package() {
+  DESTDIR="$pkgdir" cmake --install build
+  install -Dm644 libmemcached-$pkgver/LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
+}
+
+# vim:set ts=2 sw=2 et: