[arch-commits] Commit in iaito/repos (2 files)

Levente Polyak anthraxx at gemini.archlinux.org
Fri Mar 25 18:05:06 UTC 2022


    Date: Friday, March 25, 2022 @ 18:05:05
  Author: anthraxx
Revision: 1176584

archrelease: copy trunk to community-testing-x86_64

Added:
  iaito/repos/community-testing-x86_64/
  iaito/repos/community-testing-x86_64/PKGBUILD
    (from rev 1176583, iaito/trunk/PKGBUILD)

----------+
 PKGBUILD |   57 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)

Copied: iaito/repos/community-testing-x86_64/PKGBUILD (from rev 1176583, iaito/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2022-03-25 18:05:05 UTC (rev 1176584)
@@ -0,0 +1,57 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Maintainer: Santiago Torres-Arias <santiago[at]archlinux[dot]org>
+# Contributor: Aaron McDaniel (mcd1992) <'aur' at the domain 'fgthou.se'>
+
+pkgname=iaito
+_gitcommit=24a2eba21c43f42aa4535278be20ff7e957c884d
+pkgver=5.5beta0.r16.g24a2eba2
+pkgrel=1
+pkgdesc='Qt and C++ GUI for radare2 reverse engineering framework'
+url='https://github.com/radareorg/iaito'
+arch=('x86_64')
+license=('GPL3')
+depends=('radare2' 'capstone' 'qt5-base' 'qt5-svg' 'qt5-webengine' 'icu' 'python' 'jupyter'
+         'pyside2' 'python-shiboken2' 'graphviz' 'gcc-libs' 'syntax-highlighting')
+makedepends=('git' 'cmake' 'ninja' 'shiboken2' 'qt5-tools')
+optdepends=('r2ghidra: ghidra decompiler plugin')
+replaces=('r2cutter')
+source=("git+https://github.com/radareorg/iaito#commit=${_gitcommit}"
+        "git+https://github.com/radareorg/iaito-translations")
+sha512sums=('SKIP'
+            'SKIP')
+b2sums=('SKIP'
+        'SKIP')
+
+pkgver() {
+  cd iaito
+  git describe --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g' | sed 's/5.5.0.beta/5.5beta0/'
+}
+
+prepare() {
+  cd iaito
+  git config 'submodule.src/translations.url' "${srcdir}/iaito-translations"
+  git submodule update --init src/translations
+}
+
+build() {
+  cd iaito/src
+  cmake -B build \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_BUILD_TYPE=None \
+    -DIAITO_ENABLE_PYTHON=ON \
+    -DIAITO_ENABLE_PYTHON_BINDINGS=ON \
+    -DIAITO_USE_BUNDLED_RADARE2=OFF \
+    -DIAITO_USE_ADDITIONAL_RADARE2_PATHS=OFF \
+    -DIAITO_ENABLE_CRASH_REPORTS=OFF \
+    -DIAITO_ENABLE_GRAPHVIZ=ON \
+    -Wno-dev \
+    -G Ninja
+  ninja -C build
+}
+
+package() {
+  cd iaito
+  DESTDIR="${pkgdir}" ninja -C src/build install
+}
+
+# vim: ts=2 sw=2 et:



More information about the arch-commits mailing list