[arch-commits] Commit in cbindgen/repos/extra-x86_64 (PKGBUILD PKGBUILD)

[Jan Steffens]

    Date: Friday, March 25, 2022 @ 18:48:31
  Author: heftig
Revision: 440678

archrelease: copy trunk to extra-x86_64

Added:
  cbindgen/repos/extra-x86_64/PKGBUILD
    (from rev 440677, cbindgen/trunk/PKGBUILD)
Deleted:
  cbindgen/repos/extra-x86_64/PKGBUILD

----------+
 PKGBUILD |   87 +++++++++++++++++++++++++++++++------------------------------
 1 file changed, 45 insertions(+), 42 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2022-03-25 18:46:51 UTC (rev 440677)
+++ PKGBUILD	2022-03-25 18:48:31 UTC (rev 440678)
@@ -1,42 +0,0 @@
-# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
-
-pkgname=cbindgen
-pkgver=0.20.0
-pkgrel=1
-pkgdesc="A tool for generating C bindings to Rust code"
-url="https://github.com/eqrion/cbindgen"
-arch=(x86_64)
-license=(MPL2)
-depends=(gcc-libs)
-makedepends=(cargo git)
-checkdepends=(cython)
-_commit=41506d5aeb2be8d200f52d08afb0c243414eb00d  # tags/v0.20.0^0
-source=("git+https://github.com/eqrion/cbindgen#commit=$_commit")
-sha512sums=('SKIP')
-
-pkgver() {
-  cd $pkgname
-  git describe --tags | sed 's/^v//;s/-/+/g'
-}
-
-prepare() {
-  cd $pkgname
-  cargo fetch --locked --target x86_64-unknown-linux-gnu
-}
-
-build() {
-  cd $pkgname
-  cargo build --release --frozen --all-targets
-}
-
-check() {
-  cd $pkgname
-  # Tests need nightly features
-  RUSTC_BOOTSTRAP=1 cargo test --release --frozen
-}
-
-package() {
-  cd $pkgname
-  install -Dt "$pkgdir/usr/bin" target/release/cbindgen
-  install -Dt "$pkgdir/usr/share/doc/$pkgname" -m644 README.md
-}

Copied: cbindgen/repos/extra-x86_64/PKGBUILD (from rev 440677, cbindgen/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2022-03-25 18:48:31 UTC (rev 440678)
@@ -0,0 +1,45 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+
+pkgname=cbindgen
+pkgver=0.21.0
+pkgrel=1
+pkgdesc="A tool for generating C bindings to Rust code"
+url="https://github.com/eqrion/cbindgen"
+arch=(x86_64)
+license=(MPL2)
+depends=(gcc-libs)
+makedepends=(cargo git)
+checkdepends=(cython)
+_commit=b3de1dc4b438222ee8000afeeafdbe209adf337e  # tags/v0.21.0^0
+source=("git+https://github.com/eqrion/cbindgen#commit=$_commit")
+sha512sums=('SKIP')
+
+export CARGO_PROFILE_RELEASE_LTO=fat
+export CARGO_PROFILE_RELEASE_CODEGEN_UNITS=1
+
+pkgver() {
+  cd cbindgen
+  git describe --tags | sed 's/^v//;s/[^-]*-g/r&/;s/-/+/g'
+}
+
+prepare() {
+  cd cbindgen
+  cargo fetch --locked --target x86_64-unknown-linux-gnu
+}
+
+build() {
+  cd cbindgen
+  cargo build --release --frozen --all-targets
+}
+
+check() {
+  cd cbindgen
+  # Tests need nightly features
+  RUSTC_BOOTSTRAP=1 cargo test --release --frozen
+}
+
+package() {
+  cd cbindgen
+  install -Dt "$pkgdir/usr/bin" target/release/cbindgen
+  install -Dt "$pkgdir/usr/share/doc/$pkgname" -m644 README.md
+}