[arch-commits] Commit in python-graphviz/trunk (PKGBUILD)

[Caleb Maclennan]

    Date: Friday, March 25, 2022 @ 20:51:24
  Author: alerque
Revision: 1176672

upgpkg: python-graphviz 0.19.1-1

Modified:
  python-graphviz/trunk/PKGBUILD

----------+
 PKGBUILD |   58 ++++++++++++++++++++++++++++++----------------------------
 1 file changed, 30 insertions(+), 28 deletions(-)

Modified: PKGBUILD
===================================================================
--- PKGBUILD	2022-03-25 20:16:59 UTC (rev 1176671)
+++ PKGBUILD	2022-03-25 20:51:24 UTC (rev 1176672)
@@ -3,44 +3,46 @@
 
 _pkgname=graphviz
 pkgname=python-graphviz
-pkgver=0.19
-pkgrel=2
-pkgdesc="Simple Python interface for Graphviz"
-arch=('any')
-url="https://github.com/xflr6/${_pkgname}"
-license=('MIT')
-depends=('graphviz' 'python')
-makedepends=('python-setuptools')
-checkdepends=('python-pytest' 'python-pytest-mock' 'python-mock')
+pkgver=0.19.1
+pkgrel=1
+pkgdesc='Simple Python interface for Graphviz'
+arch=(any)
+url="https://github.com/xflr6/$_pkgname"
+license=(MIT)
+depends=(graphviz
+         python)
+makedepends=(python-{build,installer}
+             python-setuptools
+             python-wheel)
+checkdepends=(python-mock
+              python-pytest
+              python-pytest-mock)
 #source=("https://files.pythonhosted.org/packages/source/${_pkgname:0:1}/${_pkgname}/${_pkgname}-${pkgver}.zip")
-source=("https://github.com/xflr6/graphviz/archive/$pkgver/$_pkgname-$pkgver.tar.gz")
-sha256sums=('47da628b46d5a9f8027170f0a3926ece5f9dbf0835f950d552a0547085c1f4e6')
-b2sums=('d68acacaeff538c77484a8c63553095ea916c6e6dc24353351db57b6c9bd24429053643780461a44e5bb95e8d4cd76b5f3ca50279c93cd6ed26ea64a34d0709e')
+_archive="$_pkgname-$pkgver"
+source=("$url/archive/$pkgver/$_archive.tar.gz")
+sha256sums=('e1feb29cc94aa812ce5ad49d82176ec4e52f7addc9804be48856a1154d164b38')
+b2sums=('0422c710724ca67994131b98fc63e8f15944a8bd7064949ee0ab4e6196eadb02ed6c6d61f1699cb2e5ab875c8cf06a68078a9c34618c59d616b7c9bb96e3aa4f')
 
 prepare() {
-    cd ${_pkgname}-${pkgver}
-
-    # do not run python-coverage in unittests :/
-    sed -i 's/--cov --cov-report=term --cov-report=html//' setup.cfg
-    # don't add pointless dependency on python-mock needed on python 3.5
-    sed -i '/mock_use_standalone_module/d' setup.cfg
+	cd "$_archive"
+	# do not run python-coverage in unittests :/
+	sed -i 's/--cov --cov-report=term --cov-report=html//' setup.cfg
+	# don't add pointless dependency on python-mock needed on python 3.5
+	sed -i '/mock_use_standalone_module/d' setup.cfg
 }
 
 build(){
-    cd ${_pkgname}-${pkgver}
-
-    python setup.py build
+	cd "$_archive"
+	python -m build -wn
 }
 
 check() {
-    cd ${_pkgname}-${pkgver}/tests
-
-    python -m pytest
+	cd "$_archive/tests"
+	python -m pytest
 }
 
 package() {
-    cd ${_pkgname}-${pkgver}
-
-    python setup.py install --root="${pkgdir}" --optimize=1 --skip-build
-    install -Dm644 LICENSE.txt "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE.txt
+	cd "$_archive"
+	python -m installer -d "$pkgdir" dist/*.whl
+	install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname/" LICENSE.txt
 }