[arch-commits] Commit in lib32-at-spi2-core/repos/multilib-x86_64 (PKGBUILD PKGBUILD)

[Jan Steffens]

    Date: Sunday, March 27, 2022 @ 16:53:52
  Author: heftig
Revision: 1177225

archrelease: copy trunk to multilib-x86_64

Added:
  lib32-at-spi2-core/repos/multilib-x86_64/PKGBUILD
    (from rev 1177224, lib32-at-spi2-core/trunk/PKGBUILD)
Deleted:
  lib32-at-spi2-core/repos/multilib-x86_64/PKGBUILD

----------+
 PKGBUILD |   99 ++++++++++++++++++++++++++++++-------------------------------
 1 file changed, 49 insertions(+), 50 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2022-03-27 16:50:33 UTC (rev 1177224)
+++ PKGBUILD	2022-03-27 16:53:52 UTC (rev 1177225)
@@ -1,50 +0,0 @@
-# Maintainer:m Maxime Gauduin <alucryd at archlinux.org>
-# Contributor: jtts <jussaar at mbnet.fi>
-# Contributor: Ionut Biru <ibiru at archlinux.org>
-
-pkgname=lib32-at-spi2-core
-pkgver=2.42.0
-pkgrel=1
-pkgdesc='Protocol definitions and daemon for D-Bus at-spi'
-arch=(x86_64)
-url=https://www.gnome.org
-license=(GPL2)
-depends=(
-  at-spi2-core
-  lib32-dbus
-  lib32-glib2
-  lib32-libxtst
-)
-makedepends=(
-  git
-  gtk-doc
-  intltool
-  meson
-)
-_tag=b22b7dcfcb34f01218de0f6aa0d10b4d34fb07aa
-source=(git+https://gitlab.gnome.org/GNOME/at-spi2-core.git#tag=${_tag})
-sha256sums=(SKIP)
-
-pkgver() {
-  cd at-spi2-core
-
-  git describe --tags | sed 's/^AT_SPI2_CORE_//; s/_/./g'
-}
-
-build() {
-  export CC='gcc -m32'
-  export PKG_CONFIG_PATH=/usr/lib32/pkgconfig
-
-  arch-meson at-spi2-core build \
-    --libdir=/usr/lib32 \
-    -D docs=false \
-    -D introspection=no
-  ninja -C build
-}
-
-package() {
-  DESTDIR="${pkgdir}" ninja -C build install
-  rm -r "${pkgdir}"/{etc,usr/{include,lib,share}}
-}
-
-# vim: ts=2 sw=2 et:

Copied: lib32-at-spi2-core/repos/multilib-x86_64/PKGBUILD (from rev 1177224, lib32-at-spi2-core/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2022-03-27 16:53:52 UTC (rev 1177225)
@@ -0,0 +1,49 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: jtts <jussaar at mbnet.fi>
+# Contributor: Ionut Biru <ibiru at archlinux.org>
+
+pkgname=lib32-at-spi2-core
+pkgver=2.44.0
+pkgrel=1
+pkgdesc="Protocol definitions and daemon for D-Bus at-spi (32-bit)"
+url="https://gitlab.gnome.org/GNOME/at-spi2-core"
+arch=(x86_64)
+license=(GPL2)
+depends=(
+  at-spi2-core
+  lib32-dbus
+  lib32-glib2
+  lib32-libxtst
+)
+makedepends=(
+  git
+  meson
+)
+options=(debug)
+_commit=f38e40e8685400ddb66759aa009e18c12c898de4  # tags/AT_SPI2_CORE_2_44_0^0
+source=("git+https://gitlab.gnome.org/GNOME/at-spi2-core.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd at-spi2-core
+  git describe --tags | sed 's/^AT_SPI2_CORE_//;s/_/./g;s/-/+/g'
+}
+
+build() {
+  export CC='gcc -m32'
+  export PKG_CONFIG=i686-pc-linux-gnu-pkg-config
+
+  arch-meson at-spi2-core build \
+    --libdir=/usr/lib32 \
+    -D introspection=no \
+    -D docs=false
+  meson compile -C build
+}
+
+package() {
+  meson install -C build --destdir "$pkgdir"
+  rm -r "${pkgdir}"/{etc,usr/{include,lib,share}}
+}
+
+# vim:set sw=2 et: