[arch-commits] Commit in (eva eva/repos eva/trunk eva/trunk/PKGBUILD)

[Caleb Maclennan]

    Date: Monday, March 28, 2022 @ 18:49:27
  Author: alerque
Revision: 1177394

Migrate eva from AUR

Added:
  eva/
  eva/repos/
  eva/trunk/
  eva/trunk/PKGBUILD

----------+
 PKGBUILD |   38 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 38 insertions(+)

Added: eva/trunk/PKGBUILD
===================================================================
--- eva/trunk/PKGBUILD	                        (rev 0)
+++ eva/trunk/PKGBUILD	2022-03-28 18:49:27 UTC (rev 1177394)
@@ -0,0 +1,38 @@
+# Maintainer: Caleb Maclennan <caleb at alerque.com>
+# Contributor: Wesley Moore <wes at wezm.net>
+
+pkgname=eva
+pkgver=0.2.7
+pkgrel=2
+pkgdesc='simple calculator REPL, similar to bc(1)'
+arch=(x86_64)
+url="https://github.com/NerdyPepper/$pkgname"
+license=(GPL3)
+depends=(gcc-libs)
+makedepends=(cargo)
+options=(debug)
+_archive="$pkgname-$pkgver"
+source=("$url/archive/v$pkgver/$_archive.tar.gz")
+sha256sums=('72b2e47e987102d67c9dcbb60e26c4ff0b20e6f844d0d2b9d91c3f073374aee0')
+
+prepare() {
+	cd "$_archive"
+	cargo update # upstream release lockfile isn't synced
+	cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
+}
+
+build() {
+	cd "$_archive"
+	cargo build --frozen --release
+}
+
+check() {
+	cd "$_archive"
+	# Upstream tests broken on current Rust
+	# cargo test --frozen
+}
+
+package() {
+	cd "$_archive"
+	install -Dm0755 -t "$pkgdir/usr/bin/" "target/release/$pkgname"
+}