[arch-commits] Commit in (6 files)

[Antonio Rojas]

    Date: Tuesday, March 29, 2022 @ 07:11:42
  Author: arojas
Revision: 1177514

New jupyterlab-server checkdepends

Added:
  python-dictpath/
  python-dictpath/repos/
  python-dictpath/repos/community-x86_64/
  python-dictpath/repos/community-x86_64/PKGBUILD
  python-dictpath/trunk/
  python-dictpath/trunk/PKGBUILD

---------------------------------+
 repos/community-x86_64/PKGBUILD |   26 ++++++++++++++++++++++++++
 trunk/PKGBUILD                  |   31 +++++++++++++++++++++++++++++++
 2 files changed, 57 insertions(+)

Added: python-dictpath/repos/community-x86_64/PKGBUILD
===================================================================
--- python-dictpath/repos/community-x86_64/PKGBUILD	                        (rev 0)
+++ python-dictpath/repos/community-x86_64/PKGBUILD	2022-03-29 07:11:42 UTC (rev 1177514)
@@ -0,0 +1,26 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Fredrick Brennan <copypaste at kittens.ph>
+# Contributor: Stephan Eisvogel <eisvogel at embinet dot de>
+
+pkgname=python-pikepdf
+pkgver=5.1.0
+pkgrel=1
+pkgdesc='Read and write PDFs with Python, powered by qpdf'
+arch=(x86_64)
+url='https://github.com/pikepdf/pikepdf'
+license=(MPL2)
+makedepends=(pybind11 python-build python-installer python-wheel python-toml python-setuptools-scm-git-archive)
+depends=(python-lxml python-pillow qpdf)
+source=(https://pypi.python.org/packages/source/p/pikepdf/pikepdf-$pkgver.tar.gz)
+sha256sums=('559b3d502cc1a6813cbcb0766b0797fec034303f8f9b0734cf938fb1734e2b74')
+
+build() {
+  cd pikepdf-$pkgver
+  python -m build --wheel --no-isolation
+}
+
+package() {
+  cd pikepdf-$pkgver
+  python -m installer --destdir="$pkgdir" dist/*.whl
+  install -Dm644 LICENSE.txt -t "$pkgdir"/usr/share/licenses/$pkgname
+}

Added: python-dictpath/trunk/PKGBUILD
===================================================================
--- python-dictpath/trunk/PKGBUILD	                        (rev 0)
+++ python-dictpath/trunk/PKGBUILD	2022-03-29 07:11:42 UTC (rev 1177514)
@@ -0,0 +1,31 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+
+pkgname=python-dictpath
+_pipname=dictpath
+pkgver=0.1.3
+pkgrel=1
+pkgdesc='Object-oriented dictionary paths'
+arch=(any)
+url='https://github.com/p1c2u/dictpath'
+license=(BSD)
+depends=(python)
+makedepends=(python-build python-installer python-setuptools python-wheel)
+checkdepends=(python-pytest-cov python-pytest-flake8)
+source=(https://pypi.io/packages/source/${_pipname:0:1}/$_pipname/$_pipname-$pkgver.tar.gz)
+sha256sums=('751cde3b76b176d25f961b90c423a11a4d5ede9bd09ab0d64a85abb738c190d8')
+
+build() {
+  cd $_pipname-$pkgver
+  python -m build --wheel --no-isolation
+}
+
+check() {
+  cd $_pipname-$pkgver
+  pytest -vv
+}
+
+package() {
+  cd $_pipname-$pkgver
+  python -m installer --destdir="$pkgdir" dist/*.whl
+  install -Dm644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname
+}