[arch-commits] Commit in difftastic/repos (community-x86_64 community-x86_64/PKGBUILD)

[George Rawlinson]

    Date: Tuesday, March 29, 2022 @ 20:05:38
  Author: grawlinson
Revision: 1177685

archrelease: copy trunk to community-x86_64

Added:
  difftastic/repos/community-x86_64/
  difftastic/repos/community-x86_64/PKGBUILD
    (from rev 1177684, difftastic/trunk/PKGBUILD)

----------+
 PKGBUILD |   60 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 60 insertions(+)

Copied: difftastic/repos/community-x86_64/PKGBUILD (from rev 1177684, difftastic/trunk/PKGBUILD)
===================================================================
--- community-x86_64/PKGBUILD	                        (rev 0)
+++ community-x86_64/PKGBUILD	2022-03-29 20:05:38 UTC (rev 1177685)
@@ -0,0 +1,60 @@
+# Maintainer: George Rawlinson <grawlinson at archlinux.org>
+# Contributor: Wesley Moore <wes at wezm.net>
+
+pkgname=difftastic
+pkgver=0.24.0
+pkgrel=1
+pkgdesc="An experimental diff tool that compares files based on their syntax"
+arch=('x86_64')
+url="https://difftastic.wilfred.me.uk"
+license=('MIT')
+depends=('gcc-libs')
+makedepends=('git' 'rust' 'mdbook')
+options=('!lto')
+_commit='c15ba1e75ae6de31661d525dbbb386ac21094ca0'
+source=("$pkgname::git+https://github.com/Wilfred/difftastic.git#commit=$_commit")
+b2sums=('SKIP')
+
+pkgver() {
+  cd "$pkgname"
+
+  git describe --tags | sed 's/^v//'
+}
+
+prepare() {
+  cd "$pkgname"
+
+  # download dependencies
+  cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
+}
+
+build() {
+  cd "$pkgname"
+
+  # binary
+  cargo build --frozen --release --all-features
+
+  # documentation
+  cd manual
+  mdbook build
+}
+
+check() {
+  cd "$pkgname"
+
+  cargo test --frozen --all-features
+}
+
+package() {
+  cd "$pkgname"
+
+  # binary
+  install -vDm755 -t "$pkgdir/usr/bin" target/release/difft
+
+  # documentation
+  install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" README.md
+  cp -vr manual/book "$pkgdir/usr/share/doc/$pkgname/manual"
+
+  # license
+  install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
+}