[arch-commits] Commit in baobab/repos (3 files)

[Jan Steffens]

    Date: Wednesday, March 30, 2022 @ 19:16:43
  Author: heftig
Revision: 440996

archrelease: copy trunk to gnome-unstable-x86_64

Added:
  baobab/repos/gnome-unstable-x86_64/
  baobab/repos/gnome-unstable-x86_64/PKGBUILD
    (from rev 440995, baobab/trunk/PKGBUILD)
  baobab/repos/gnome-unstable-x86_64/no-mimetype.diff
    (from rev 440995, baobab/trunk/no-mimetype.diff)

------------------+
 PKGBUILD         |   44 ++++++++++++++++++++++++++++++++++++++++++++
 no-mimetype.diff |   12 ++++++++++++
 2 files changed, 56 insertions(+)

Copied: baobab/repos/gnome-unstable-x86_64/PKGBUILD (from rev 440995, baobab/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD	2022-03-30 19:16:43 UTC (rev 440996)
@@ -0,0 +1,44 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Ionut Biru <ibiru at archlinux.org>
+
+pkgname=baobab
+pkgver=42.0
+pkgrel=1
+pkgdesc="A graphical directory tree analyzer"
+url="https://wiki.gnome.org/Apps/DiskUsageAnalyzer"
+arch=(x86_64)
+license=(GPL2)
+depends=(dconf gtk4 gsettings-desktop-schemas librsvg libadwaita)
+makedepends=(vala gobject-introspection yelp-tools appstream-glib git meson)
+groups=(gnome)
+options=(debug)
+_commit=bffc1c040ee75e0cb0675d0bc1a59619ff57366c  # tags/42.0^0
+source=("git+https://gitlab.gnome.org/GNOME/baobab.git#commit=$_commit"
+        no-mimetype.diff)
+sha256sums=('SKIP'
+            '958a85fe3a2001d16ebcf71b51888f260508af87224a0de3410a6bbe685e59d0')
+
+pkgver() {
+  cd baobab
+  git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
+}
+
+prepare() {
+  cd baobab
+
+  # https://bugs.archlinux.org/task/31861
+  git apply -3 ../no-mimetype.diff
+}
+
+build() {
+  arch-meson baobab build
+  meson compile -C build
+}
+
+check() {
+  meson test -C build --print-errorlogs
+}
+
+package() {
+  meson install -C build --destdir "$pkgdir"
+}

Copied: baobab/repos/gnome-unstable-x86_64/no-mimetype.diff (from rev 440995, baobab/trunk/no-mimetype.diff)
===================================================================
--- gnome-unstable-x86_64/no-mimetype.diff	                        (rev 0)
+++ gnome-unstable-x86_64/no-mimetype.diff	2022-03-30 19:16:43 UTC (rev 440996)
@@ -0,0 +1,12 @@
+diff --git i/data/org.gnome.baobab.desktop.in w/data/org.gnome.baobab.desktop.in
+index b5e2a05..219eb2e 100644
+--- i/data/org.gnome.baobab.desktop.in
++++ w/data/org.gnome.baobab.desktop.in
+@@ -10,7 +10,6 @@ Icon=org.gnome.baobab
+ Terminal=false
+ Type=Application
+ StartupNotify=true
+-MimeType=inode/directory;
+ Categories=GTK;GNOME;System;Filesystem;X-GNOME-Utilities;
+ DBusActivatable=true
+ X-GNOME-UsesNotifications=true