[arch-commits] Commit in evince/repos (2 files)

[Jan Steffens]

    Date: Wednesday, March 30, 2022 @ 19:42:58
  Author: heftig
Revision: 441005

archrelease: copy trunk to gnome-unstable-x86_64

Added:
  evince/repos/gnome-unstable-x86_64/
  evince/repos/gnome-unstable-x86_64/PKGBUILD
    (from rev 441004, evince/trunk/PKGBUILD)

----------+
 PKGBUILD |   67 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 67 insertions(+)

Copied: evince/repos/gnome-unstable-x86_64/PKGBUILD (from rev 441004, evince/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD	2022-03-30 19:42:58 UTC (rev 441005)
@@ -0,0 +1,67 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+
+pkgbase=evince
+pkgname=(evince evince-lib-docs)
+pkgver=42.1
+pkgrel=1
+pkgdesc="Document viewer (PDF, PostScript, XPS, djvu, dvi, tiff, cbr, cbz, cb7, cbt)"
+url="https://wiki.gnome.org/Apps/Evince"
+arch=(x86_64)
+license=(GPL)
+depends=(gtk3 libgxps libspectre gsfonts poppler-glib djvulibre t1lib dconf libsecret libsynctex
+         gsettings-desktop-schemas gnome-desktop libarchive gst-plugins-base-libs gspell libhandy
+         gvfs)
+makedepends=(libnautilus-extension texlive-bin gobject-introspection gi-docgen git meson
+             appstream-glib yelp-tools)
+options=(debug)
+_commit=67084a4f4ec10445bf8f3ef2cf98cb0ccaabcb19  # tags/42.1^0
+source=("git+https://gitlab.gnome.org/GNOME/evince.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd evince
+  git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
+}
+
+prepare() {
+  cd evince
+}
+  
+build() {
+  arch-meson evince build -D ps=enabled
+  meson compile -C build
+}
+
+check() {
+  meson test -C build --print-errorlogs
+}
+
+_pick() {
+  local p="$1" f d; shift
+  for f; do
+    d="$srcdir/$p/${f#$pkgdir/}"
+    mkdir -p "$(dirname "$d")"
+    mv "$f" "$d"
+    rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
+  done
+}
+
+package_evince() {
+  provides=(libev{document,view}3.so)
+  optdepends=('texlive-bin: DVI support')
+  groups=(gnome)
+
+  meson install -C build --destdir "$pkgdir"
+
+  _pick lib-docs "$pkgdir"/usr/share/doc/lib*
+}
+
+package_evince-lib-docs() {
+  pkgdesc+=" (library API documentation)"
+  depends=()
+
+  mv lib-docs/* "$pkgdir"
+}
+
+# vim:set sw=2 et: