[arch-commits] Commit in libgweather-4/trunk (PKGBUILD disable-metar-test.diff)
Jan Steffens
heftig at gemini.archlinux.org
Wed Mar 30 20:23:53 UTC 2022
Date: Wednesday, March 30, 2022 @ 20:23:53
Author: heftig
Revision: 441012
4.0.0-1
Added:
libgweather-4/trunk/PKGBUILD
libgweather-4/trunk/disable-metar-test.diff
-------------------------+
PKGBUILD | 59 ++++++++++++++++++++++++++++++++++++++++++++++
disable-metar-test.diff | 12 +++++++++
2 files changed, 71 insertions(+)
Added: PKGBUILD
===================================================================
--- PKGBUILD (rev 0)
+++ PKGBUILD 2022-03-30 20:23:53 UTC (rev 441012)
@@ -0,0 +1,59 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+
+pkgbase=libgweather-4
+pkgname=(libgweather-4 libgweather-4-docs)
+pkgver=4.0.0
+pkgrel=1
+pkgdesc="Location and timezone database and weather-lookup library"
+url="https://wiki.gnome.org/Projects/LibGWeather"
+arch=(x86_64)
+license=(LGPL)
+depends=(libsoup gtk4 geocode-glib dconf)
+makedepends=(gobject-introspection vala git gi-docgen meson python-gobject)
+checkdepends=(python-pylint)
+options=(debug)
+_commit=6ac9872a5a06863f6c84f6ac836cede78b401691 # tags/4.0.0^0
+source=("git+https://gitlab.gnome.org/GNOME/libgweather.git#commit=$_commit"
+ disable-metar-test.diff)
+sha256sums=('SKIP'
+ 'c11eb9ad69f8354e5baeef5581038ef0cd5ce2f032dd48f3df29e34fc900dd5a')
+
+pkgver() {
+ cd libgweather
+ git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
+}
+
+prepare() {
+ cd libgweather
+
+ # Disable metar test, depends on unstable online service
+ git apply -3 ../disable-metar-test.diff
+}
+
+build() {
+ arch-meson libgweather build -D gtk_doc=true
+ meson compile -C build
+}
+
+check() {
+ meson test -C build --print-errorlogs
+}
+
+package_libgweather-4() {
+ provides=(libgweather-4.so)
+
+ meson install -C build --destdir "$pkgdir"
+
+ mkdir -p doc/usr/share
+ mv {"$pkgdir",doc}/usr/share/doc
+}
+
+package_libgweather-4-docs() {
+ pkgdesc+=" (documentation)"
+ depends=()
+
+ mv doc/* "$pkgdir"
+}
+
+# vim:set sw=2 et:
Added: disable-metar-test.diff
===================================================================
--- disable-metar-test.diff (rev 0)
+++ disable-metar-test.diff 2022-03-30 20:23:53 UTC (rev 441012)
@@ -0,0 +1,12 @@
+diff --git i/libgweather/tests/meson.build w/libgweather/tests/meson.build
+index eefe2a3f..c49b41cf 100644
+--- i/libgweather/tests/meson.build
++++ w/libgweather/tests/meson.build
+@@ -20,7 +20,6 @@ gweather_tests = [
+ },
+ },
+ { 'name': 'timezones' },
+- { 'name': 'metar' },
+ ]
+
+ foreach t: gweather_tests
More information about the arch-commits
mailing list