[arch-commits] Commit in (4 files)

[George Rawlinson]

    Date: Wednesday, March 30, 2022 @ 21:41:30
  Author: grawlinson
Revision: 1177866

addpkg: mdbook-linkcheck 0.7.6-2

Added:
  mdbook-linkcheck/
  mdbook-linkcheck/repos/
  mdbook-linkcheck/trunk/
  mdbook-linkcheck/trunk/PKGBUILD

----------+
 PKGBUILD |   53 +++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

Added: mdbook-linkcheck/trunk/PKGBUILD
===================================================================
--- mdbook-linkcheck/trunk/PKGBUILD	                        (rev 0)
+++ mdbook-linkcheck/trunk/PKGBUILD	2022-03-30 21:41:30 UTC (rev 1177866)
@@ -0,0 +1,53 @@
+# Maintainer: George Rawlinson <grawlinson at archlinux.org>
+
+pkgname=mdbook-linkcheck
+pkgver=0.7.6
+pkgrel=2
+pkgdesc="A mdbook backend which will check all links in a document are valid"
+arch=('x86_64')
+url="https://github.com/Michael-F-Bryan/mdbook-linkcheck"
+license=('MIT')
+depends=('mdbook')
+makedepends=('git' 'rust')
+options=('!lto')
+_commit='0973643dc6fbe9305de0626d2e1e131f7b1cbdbf'
+source=("$pkgname::git+$url.git#commit=$_commit")
+b2sums=('SKIP')
+
+pkgver() {
+  cd "$pkgname"
+
+  git describe --tags | sed 's/^v//'
+}
+
+prepare() {
+  cd "$pkgname"
+
+  # download dependencies
+  cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
+}
+
+build() {
+  cd "$pkgname"
+
+  cargo build --frozen --release --all-features
+}
+
+check() {
+  cd "$pkgname"
+
+  cargo test --frozen --all-features
+}
+
+package() {
+  cd "$pkgname"
+
+  # binary
+  install -vDm755 -t "$pkgdir/usr/bin" "target/release/$pkgname"
+
+  # documentation
+  install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" README.md
+
+  # license
+  install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
+}