[arch-commits] Commit in pypiserver/trunk (PKGBUILD)

[David Runge]

    Date: Monday, May 2, 2022 @ 12:46:10
  Author: dvzrv
Revision: 1192231

upgpkg: pypiserver 1.5.0-1: Upgrade to 1.5.0.

Remove unneeded quotes and curly braces.
Add python-watchdog as new optdepends and python-httpx as new checkdepends.
Remove twine from checkdepends and exclude tests using it (we do not care about deployment).
Switch to PEP517.

Modified:
  pypiserver/trunk/PKGBUILD

----------+
 PKGBUILD |   48 ++++++++++++++++++++++++++----------------------
 1 file changed, 26 insertions(+), 22 deletions(-)

Modified: PKGBUILD
===================================================================
--- PKGBUILD	2022-05-02 12:36:57 UTC (rev 1192230)
+++ PKGBUILD	2022-05-02 12:46:10 UTC (rev 1192231)
@@ -1,37 +1,41 @@
 # Maintainer: David Runge <dvzrv at archlinux.org>
 
 pkgname=pypiserver
-pkgver=1.4.2
-pkgrel=3
+pkgver=1.5.0
+pkgrel=1
 pkgdesc="Minimal PyPI server for uploading and downloading packages with pip/easy_install"
-arch=('any')
+arch=(any)
 url="https://github.com/pypiserver/pypiserver"
-license=('MIT' 'zlib')
-depends=('python')
-makedepends=('python-setuptools' 'python-setuptools-git' 'python-wheel')
-checkdepends=('python-passlib' 'python-pip' 'python-pytest' 'python-webtest' 'twine')
-optdepends=('python-passlib: for authentication')
-source=("$pkgname-$pkgver.tar.gz::https://github.com/${pkgname}/${pkgname}/archive/refs/tags/v${pkgver}.tar.gz")
-sha512sums=('8597a6a7e83cb3f5ead3418ee91167e1764c123b244c05397fa892c8ebe84b58569f27ce85cd9849d6a41d20342de21cf9cc46e00b233d9d94d0540470e1c49b')
-b2sums=('fe9a41c35d601ee20f2cfe0773ce341b8c8fe387a2b825d1e6d669d5f358846b436158beb8a1222fa33cf1841cad5aceacc0f5063f899445ad15ca9eb5b8efd7')
+license=(MIT zlib)
+depends=(python)
+makedepends=(python-build python-installer python-setuptools python-setuptools-git python-wheel)
+checkdepends=(python-httpx python-passlib python-pip python-pytest python-watchdog python-webtest)
+optdepends=(
+  'python-passlib: for authentication'
+  'python-watchdog: for cache'
+)
+source=($pkgname-$pkgver.tar.gz::https://github.com/$pkgname/$pkgname/archive/refs/tags/v$pkgver.tar.gz)
+sha512sums=('c93e724a3aa6ec265d483c2989129292a05132d3d52db6d9b9c1429610ee23b56e106c9389bdfaad142f34071ee258bdd4291668c11f8bb412df043bf4555611')
+b2sums=('bfc0760982f97e93357702342eb5b1776f72c43e66742a8741ee2ba3109839006e99e49b65e04380097500c400e09bce77b74fc5f9072c7670349817ae3a73cb')
 validpgpkeys=('0BFB950A1851C0E7EE46D9BCAF5C892A5573ABED') # Matthew Planchard (2020-06-22-mininix) <msplanchard at gmail.com>
 
 build() {
-  cd "$pkgname-$pkgver"
-  python setup.py build
+  cd $pkgname-$pkgver
+  python -m build --wheel --no-isolation
 }
 
 check() {
-  cd "$pkgname-$pkgver"
-  export PYTHONPATH="build:${PYTHONPATH}"
-  pytest -v
+  local _site_packages=$(python -c "import site; print(site.getsitepackages()[0])")
+
+  cd $pkgname-$pkgver
+  python -m installer --destdir=test_dir dist/*.whl
+  export PYTHONPATH="test_dir/$_site_packages:$PYTHONPATH"
+  pytest -vv --ignore docker/test_docker.py -k "not test_twine"
 }
 
 package() {
-  cd "$pkgname-$pkgver"
-  python setup.py install --skip-build \
-                          --optimize=1 \
-                          --root="${pkgdir}"
-  install -vDm 644 {AUTHORS,CHANGES,README}.rst -t "${pkgdir}/usr/share/doc/${pkgname}/"
-  install -vDm 644 LICENSE.txt -t "${pkgdir}/usr/share/licenses/${pkgname}/"
+  cd $pkgname-$pkgver
+  python -m installer --destdir="$pkgdir" dist/$pkgname*.whl
+  install -vDm 644 {AUTHORS,CHANGES,README}.rst -t "$pkgdir/usr/share/doc/$pkgname/"
+  install -vDm 644 LICENSE.txt -t "$pkgdir/usr/share/licenses/$pkgname/"
 }