[arch-commits] Commit in lib32-libxml2/repos (2 files)

[Jan Steffens]

    Date: Monday, May 2, 2022 @ 17:24:36
  Author: heftig
Revision: 1192289

archrelease: copy trunk to multilib-testing-x86_64

Added:
  lib32-libxml2/repos/multilib-testing-x86_64/
  lib32-libxml2/repos/multilib-testing-x86_64/PKGBUILD
    (from rev 1192287, lib32-libxml2/trunk/PKGBUILD)

----------+
 PKGBUILD |   66 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 66 insertions(+)

Copied: lib32-libxml2/repos/multilib-testing-x86_64/PKGBUILD (from rev 1192287, lib32-libxml2/trunk/PKGBUILD)
===================================================================
--- multilib-testing-x86_64/PKGBUILD	                        (rev 0)
+++ multilib-testing-x86_64/PKGBUILD	2022-05-02 17:24:36 UTC (rev 1192289)
@@ -0,0 +1,66 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+# Contributor: Tom Gundersen <teg at jklm.no>
+# Contributor: John Proctor <jproctor at prium.net>
+
+pkgname=lib32-libxml2
+pkgver=2.9.14
+pkgrel=1
+pkgdesc='XML parsing library, version 2 (32-bit)'
+url='http://www.xmlsoft.org/'
+arch=(x86_64)
+license=(MIT)
+depends=(lib32-zlib lib32-readline lib32-ncurses lib32-xz lib32-icu libxml2)
+makedepends=(git)
+provides=(libxml2.so)
+options=(debug)
+_commit=7846b0a677f8d3ce72486125fa281e92ac9970e8  # tags/v2.9.14^0
+source=("git+https://gitlab.gnome.org/GNOME/libxml2.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd libxml2
+  git describe --tags | sed 's/-rc/rc/;s/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+prepare() {
+  mkdir build
+
+  cd libxml2
+
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  export CC="gcc -m32"
+  export CXX="g++ -m32"
+  export PKG_CONFIG="i686-pc-linux-gnu-pkg-config"
+
+  cd build
+
+  ../libxml2/configure \
+    --prefix=/usr \
+    --libdir=/usr/lib32 \
+    --with-threads \
+    --with-history \
+    --without-python \
+    --with-icu
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0 /g' libtool
+  make
+}
+
+check() {
+  make -C build check
+}
+
+package() {
+  make -C build DESTDIR="$pkgdir" install
+
+  rm -r "$pkgdir"/usr/{include,share,bin}
+  rm "$pkgdir/usr/lib32/xml2Conf.sh"
+
+  install -Dm 644 build/COPYING -t "$pkgdir/usr/share/licenses/$pkgname"
+}
+
+# vim:set sw=2 et: