[arch-commits] Commit in baresip/repos (2 files)

[Alexander Epaneshnikov]

    Date: Wednesday, May 4, 2022 @ 10:57:04
  Author: alex19ep
Revision: 1193358

archrelease: copy trunk to community-staging-x86_64

Added:
  baresip/repos/community-staging-x86_64/
  baresip/repos/community-staging-x86_64/PKGBUILD
    (from rev 1193357, baresip/trunk/PKGBUILD)

----------+
 PKGBUILD |   56 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)

Copied: baresip/repos/community-staging-x86_64/PKGBUILD (from rev 1193357, baresip/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-05-04 10:57:04 UTC (rev 1193358)
@@ -0,0 +1,56 @@
+# Maintainer: Alexander Epaneshnikov <alex19ep at archlinux.org>
+# Contributor: Andrew Sun <adsun701 at gmail dot com>
+# Contributor: Dmitrij D. Czarkoff <czarkoff at gmail dot com>
+
+pkgname=baresip
+pkgver=2.3.0
+pkgrel=1
+pkgdesc="portable and modular SIP User-Agent with audio and video support"
+arch=('x86_64')
+url="http://www.creytiv.com/baresip.html"
+license=('BSD')
+depends=(libre.so librem.so openssl)
+optdepends=('libfdk-aac: AAC audio codec'
+            'alsa-lib: ALSA audio driver'
+            'opencore-amr: Adaptive Multi-Rate (AMR) audio codec'
+            'aom: (av1 module}'
+            'codec2: CODEC2 low-bitrate speech audio codec'
+            'ffmpeg: (avcodec, avformat, h265 modules)'
+            'gsm: (gsm module)'
+            'gst-plugins-bad: (gst1, gst_video1 modules)'
+            'gst-plugins-base: (gst1, gst_video1 modules)'
+            'gst-plugins-good: (gst1, gst_video1 modules)'
+            'gst-plugins-ugly: (gst1, gst_video1 modules)'
+            'gtk3: gtk+ user interface'
+            'jack2: JACK Audio Connection Kit audio driver'
+            'lame: MPA audio codec'
+            'libvpx: (vpx module)'
+            'libsndfile: (sndfile module)'
+            'libpng: Snapshot video module'
+            'libpulse: Pulseaudio audio driver'
+            'libx11: (x11, x11grab modules)'
+            'mpg123: (rst module)'
+            'opus: (opus module)'
+            'portaudio: Portaudio audio driver'
+            'sdl2: (sdl2 module)'
+            'spandsp: (g722, g726,plc modules)'
+            'speexdsp: (speex_aec, speex_pp modules)'
+            'sndio: sndio audio driver'
+            'v4l-utils: (v4l2 module)')
+makedepends=(${optdepends[@]/%:*/} python)
+source=("${pkgname}-${pkgver}.tar.gz"::"https://github.com/baresip/baresip/archive/v${pkgver}.tar.gz")
+sha256sums=('eeb3189733cd4a727204268c216ca4656a0ac24b761169692d241ea887059a95')
+
+build() {
+  cd ${pkgname}-${pkgver}
+  export LFLAGS=$LDFLAGS
+  make RELEASE=1 V=1 USE_GST= USE_GST_VIDEO= DESTDIR="/usr" PREFIX="/usr"
+}
+
+package() {
+  cd ${pkgname}-${pkgver}
+  export LFLAGS=$LDFLAGS
+  make RELEASE=1 USE_GST= USE_GST_VIDEO= PREFIX="/usr" \
+    DESTDIR="$pkgdir/" install
+  install -vDm644 docs/COPYING "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
+}