[arch-commits] Commit in gimagereader/repos (3 files)
Jelle van der Waa
jelle at gemini.archlinux.org
Wed May 4 20:19:50 UTC 2022
Date: Wednesday, May 4, 2022 @ 20:19:49
Author: jelle
Revision: 1194485
archrelease: copy trunk to community-staging-x86_64
Added:
gimagereader/repos/community-staging-x86_64/
gimagereader/repos/community-staging-x86_64/PKGBUILD
(from rev 1194484, gimagereader/trunk/PKGBUILD)
gimagereader/repos/community-staging-x86_64/openmp.patch
(from rev 1194484, gimagereader/trunk/openmp.patch)
--------------+
PKGBUILD | 70 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++
openmp.patch | 26 +++++++++++++++++++++
2 files changed, 96 insertions(+)
Copied: gimagereader/repos/community-staging-x86_64/PKGBUILD (from rev 1194484, gimagereader/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD (rev 0)
+++ community-staging-x86_64/PKGBUILD 2022-05-04 20:19:49 UTC (rev 1194485)
@@ -0,0 +1,70 @@
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+# Contributor: Caleb Maclennan <caleb at alerque.com>
+
+pkgbase=gimagereader
+pkgname=(gimagereader-gtk gimagereader-qt gimagereader-common)
+pkgver=3.4.0
+pkgrel=4
+url='https://github.com/manisandro/gImageReader'
+pkgdesc='Gtk/Qt front-end to tesseract-ocr'
+arch=('x86_64')
+license=('GPL3')
+depends=('djvulibre' 'gtksourceviewmm' 'gtkspellmm' 'libtesseract.so' 'libxml++' 'libzip' 'podofo' 'poppler-glib'
+ 'poppler-qt6' 'qt6-imageformats' 'qtspell' 'quazip-qt6' 'sane' 'tesseract')
+makedepends=('cmake' 'intltool' 'ninja' 'python-gobject')
+source=("$url/releases/download/v$pkgver/$pkgbase-$pkgver.tar.xz"
+ 'openmp.patch')
+sha256sums=('b55cfe9212fa16bf2d5a7ca0fc549454812b265ac7d4aa34697947b20eecf425'
+ 'ee84de7fee390ee54152b4e332e50d8f585b0c9a3aa8b40a04f865b5250607c2')
+
+prepare() {
+ cd $pkgbase-$pkgver
+
+ # Run OpenMP once before calling tesseract
+ # https://github.com/manisandro/gImageReader/issues/285
+ patch -Np1 -i ../openmp.patch
+
+}
+
+build() {
+ cmake -S $pkgbase-$pkgver -B build-gtk -G Ninja \
+ -DCMAKE_INSTALL_PREFIX='/usr' \
+ -DINTERFACE_TYPE=gtk
+ cmake --build build-gtk
+
+ cmake -S $pkgbase-$pkgver -B build-qt -G Ninja \
+ -DCMAKE_INSTALL_PREFIX='/usr' \
+ -DINTERFACE_TYPE=qt6
+ cmake --build build-qt
+}
+
+package_gimagereader-gtk() {
+ pkgdesc='Gtk front-end to tesseract-ocr'
+ depends=('gimagereader-common' 'djvulibre' 'gtksourceviewmm' 'gtkspellmm' 'libxml++' 'libzip'
+ 'podofo' 'poppler-glib' 'sane' 'tesseract')
+
+ DESTDIR="$pkgdir" cmake --install build-gtk
+
+ # Split gimagereader-common
+ mkdir gimagereader-common
+ mv "$pkgdir"/usr/share/{doc,icons,locale} gimagereader-common
+}
+
+package_gimagereader-qt() {
+ pkgdesc='Qt front-end to tesseract-ocr'
+ depends=('gimagereader-common' 'djvulibre' 'podofo' 'poppler-qt6' 'qt6-imageformats' 'qtspell'
+ 'quazip-qt6' 'sane' 'tesseract')
+
+ DESTDIR="$pkgdir" cmake --install build-qt
+
+ # Split gimagereader-common
+ rm -r "$pkgdir"/usr/share/{doc,icons,locale}
+}
+
+package_gimagereader-common() {
+ pkgdesc='Common files for gImageReader'
+ depends=('hicolor-icon-theme')
+
+ mkdir -p "$pkgdir"/usr/share
+ mv gimagereader-common/* "$pkgdir/usr/share"
+}
Copied: gimagereader/repos/community-staging-x86_64/openmp.patch (from rev 1194484, gimagereader/trunk/openmp.patch)
===================================================================
--- community-staging-x86_64/openmp.patch (rev 0)
+++ community-staging-x86_64/openmp.patch 2022-05-04 20:19:49 UTC (rev 1194485)
@@ -0,0 +1,26 @@
+From 122ed08d72265e3abb02c48c4be804d793058fc9 Mon Sep 17 00:00:00 2001
+From: Philip Rinn <rinni at inventati.org>
+Date: Fri, 5 Jan 2018 15:22:47 +0100
+Subject: [PATCH] Run OpenMP once before calling tesseract (fixes: #285)
+
+---
+ gtk/src/main.cc | 6 ++++++
+ 1 file changed, 6 insertions(+)
+
+diff --git a/gtk/src/main.cc b/gtk/src/main.cc
+index a2668e4..9fec77a 100644
+--- a/gtk/src/main.cc
++++ b/gtk/src/main.cc
+@@ -94,6 +94,12 @@ int main (int argc, char *argv[]) {
+ }
+ #endif
+
++ // Run OpenMP once before tesseract is called, otherwise it might be
++ // _very_ slow, see https://github.com/manisandro/gImageReader/issues/285
++ // Sleep 1 millisecond to prevent being optimized out.
++ #pragma omp parallel for schedule(static)
++ for(int i = 0; i < 1; i++) { sleep(1); }
++
+ std::string localeDir = Glib::build_filename(pkgDir, "share", "locale");
+
+ bindtextdomain(GETTEXT_PACKAGE, localeDir.c_str());
More information about the arch-commits
mailing list