[arch-commits] Commit in gitlab-exporter/repos (2 files)
Leonidas Spyropoulos
artafinde at gemini.archlinux.org
Thu May 5 12:58:01 UTC 2022
Date: Thursday, May 5, 2022 @ 12:58:01
Author: artafinde
Revision: 1195501
archrelease: copy trunk to community-x86_64
Added:
gitlab-exporter/repos/community-x86_64/
gitlab-exporter/repos/community-x86_64/PKGBUILD
(from rev 1195500, gitlab-exporter/trunk/PKGBUILD)
----------+
PKGBUILD | 43 +++++++++++++++++++++++++++++++++++++++++++
1 file changed, 43 insertions(+)
Copied: gitlab-exporter/repos/community-x86_64/PKGBUILD (from rev 1195500, gitlab-exporter/trunk/PKGBUILD)
===================================================================
--- community-x86_64/PKGBUILD (rev 0)
+++ community-x86_64/PKGBUILD 2022-05-05 12:58:01 UTC (rev 1195501)
@@ -0,0 +1,43 @@
+# Maintainer: Leonidas Spyropoulos <artafinde at archlinux.org>
+
+pkgname=gitlab-exporter
+pkgver=0.1.0
+pkgrel=1
+pkgdesc='A Gitlab prometheus metric exporter'
+arch=('x86_64')
+url='https://gitlab.archlinux.org/artafinde/gitlab-exporter'
+license=('MIT')
+depends=('gcc-libs' 'openssl')
+makedepends=('cargo' 'git')
+source=("git+$url.git?signed#tag=v$pkgver")
+b2sums=('SKIP')
+validpgpkeys=(
+ 'B4B759625D4633430B74877059E43E106B247368' # Leonidas Spyropoulos <artafinde at archlinux.org>
+ )
+
+prepare() {
+ cd "${pkgname}"
+ cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
+}
+
+build() {
+ cd "${pkgname}"
+ export RUSTUP_TOOLCHAIN=stable
+ export CARGO_TARGET_DIR=target
+ CFLAGS+=' -ffat-lto-objects'
+ cargo build --release --frozen
+}
+
+check() {
+ cd "${pkgname}"
+ export RUSTUP_TOOLCHAIN=stable
+ CFLAGS+=' -ffat-lto-objects'
+ cargo test --frozen -- --test-threads 1
+}
+
+package() {
+ cd "${pkgname}"
+ install -Dm755 target/release/${pkgname} -t "${pkgdir}"/usr/bin
+ install -Dm644 README.md -t "${pkgdir}"/usr/share/doc/${pkgname}
+ install -Dm644 LICENSE -t "${pkgdir}"/usr/share/licenses/${pkgname}
+}
More information about the arch-commits
mailing list