[arch-commits] Commit in (4 files)
Jelle van der Waa
jelle at gemini.archlinux.org
Fri May 6 15:24:26 UTC 2022
Date: Friday, May 6, 2022 @ 15:24:25
Author: jelle
Revision: 1196016
osbuild-composer initial commit
Added:
osbuild-composer/
osbuild-composer/repos/
osbuild-composer/trunk/
osbuild-composer/trunk/PKGBUILD
----------+
PKGBUILD | 56 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 56 insertions(+)
Added: osbuild-composer/trunk/PKGBUILD
===================================================================
--- osbuild-composer/trunk/PKGBUILD (rev 0)
+++ osbuild-composer/trunk/PKGBUILD 2022-05-06 15:24:25 UTC (rev 1196016)
@@ -0,0 +1,56 @@
+# Maintainer: Achilleas Koutsou <achilleas at koutsou.net>
+# Maintainer: Jelle van der Waa <jelle at archlinux.org>
+
+pkgname=osbuild-composer
+pkgdesc='An HTTP service for building bootable OS images'
+pkgver=51
+pkgrel=1
+url="https://www.osbuild.org"
+arch=(x86_64)
+license=(Apache)
+depends=('dnf' 'qemu' 'osbuild' 'systemd')
+makedepends=('go' 'systemd')
+optdepends=()
+source=($pkgname-$pkgver.tar.gz::https://github.com/osbuild/osbuild-composer/archive/refs/tags/v${pkgver}.tar.gz)
+sha256sums=('33043ab3ea3c6e93176b61430d5c5ea5ff77f4cf3ecc150acf08bbe4fd05c7b0')
+
+prepare() {
+ cd $pkgname-$pkgver
+ mkdir -p build
+
+ # Arch doesn't use /usr/libexec: edit service files
+ sed -i 's,/usr/libexec,/usr/lib,g' distribution/osbuild-*.service
+}
+
+build() {
+ cd $pkgname-$pkgver
+ export LDFLAGS="-ldflags=-X=github.com/osbuild/osbuild-composer/internal/common.RpmVersion=${pkgname}-${pkgver}-${pkgrel}.${arch}"
+ export GOFLAGS="-buildmode=pie -trimpath -mod=vendor -modcacherw ${LDFLAGS}"
+
+ go build -o build/osbuild-composer ./cmd/osbuild-composer
+ go build -o build/osbuild-worker ./cmd/osbuild-worker
+}
+
+package() {
+ cd $pkgname-$pkgver
+
+ # binaries
+ install -Dm755 "build/osbuild-composer" "${pkgdir}/usr/lib/osbuild-composer/osbuild-composer"
+ install -Dm755 "build/osbuild-worker" "${pkgdir}/usr/lib/osbuild-composer/osbuild-worker"
+ install -Dm755 "dnf-json" "${pkgdir}/usr/lib/osbuild-composer/dnf-json"
+
+ # sysusers
+ install -Dm644 distribution/osbuild-composer.conf "${pkgdir}/usr/lib/sysusers.d/osbuild-composer.conf"
+
+ # systemd units
+ mkdir -p "${pkgdir}/usr/lib/systemd/system"
+ install -Dm644 distribution/*.service "${pkgdir}/usr/lib/systemd/system/"
+ install -Dm644 distribution/*.socket "${pkgdir}/usr/lib/systemd/system/"
+
+ # repositories
+ mkdir -p "${pkgdir}/usr/share/osbuild-composer/repositories"
+ install -Dm644 repositories/*.json "${pkgdir}/usr/share/osbuild-composer/repositories"
+
+ # license
+ install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}
More information about the arch-commits
mailing list