[arch-commits] Commit in haskell-servant/repos (2 files)

[Felix Yan]

    Date: Tuesday, May 10, 2022 @ 08:07:24
  Author: felixonmars
Revision: 1197072

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-servant/repos/community-staging-x86_64/
  haskell-servant/repos/community-staging-x86_64/PKGBUILD
    (from rev 1197071, haskell-servant/trunk/PKGBUILD)

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Copied: haskell-servant/repos/community-staging-x86_64/PKGBUILD (from rev 1197071, haskell-servant/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-05-10 08:07:24 UTC (rev 1197072)
@@ -0,0 +1,52 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=servant
+pkgname=haskell-servant
+pkgver=0.18.3
+pkgrel=71
+pkgdesc="A family of combinators for defining webservices APIs"
+url="http://haskell-servant.readthedocs.org/"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-base-compat' 'haskell-aeson' 'haskell-attoparsec'
+         'haskell-bifunctors' 'haskell-case-insensitive' 'haskell-http-api-data'
+         'haskell-http-media' 'haskell-http-types' 'haskell-mmorph' 'haskell-network-uri'
+         'haskell-quickcheck' 'haskell-tagged' 'haskell-sop-core' 'haskell-singleton-bool'
+         'haskell-string-conversions' 'haskell-vault')
+makedepends=('ghc' 'uusi' 'haskell-hspec' 'haskell-quickcheck-instances')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('818569dc38fdb5df5a489c4a6622e65698439fbf8c24d4969a84728a1acd33966aeb55300c2d9e2381d59328fc12e9867d37b83a1fbb1e3b59b386700abc595e')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    uusi -u base-compat -u hspec -u mmorph $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}