[arch-commits] Commit in (4 files)
George Rawlinson
grawlinson at gemini.archlinux.org
Wed May 11 03:34:09 UTC 2022
Date: Wednesday, May 11, 2022 @ 03:34:09
Author: grawlinson
Revision: 1198270
addpkg: cl-flexi-streams 1.0.19.r4-1
Added:
cl-flexi-streams/
cl-flexi-streams/repos/
cl-flexi-streams/trunk/
cl-flexi-streams/trunk/PKGBUILD
----------+
PKGBUILD | 51 +++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 51 insertions(+)
Added: cl-flexi-streams/trunk/PKGBUILD
===================================================================
--- cl-flexi-streams/trunk/PKGBUILD (rev 0)
+++ cl-flexi-streams/trunk/PKGBUILD 2022-05-11 03:34:09 UTC (rev 1198270)
@@ -0,0 +1,51 @@
+# Maintainer: George Rawlinson <grawlinson at archlinux.org>
+
+pkgname=cl-flexi-streams
+_pkgname="${pkgname#cl-}"
+pkgver=1.0.19.r4.g74a1027
+pkgrel=1
+pkgdesc='Flexible bivalent streams for Common Lisp'
+arch=('any')
+url='https://edicl.github.io/flexi-streams/'
+license=('BSD')
+depends=('common-lisp' 'cl-asdf' 'cl-trivial-gray-streams')
+makedepends=('git' 'sbcl')
+_commit='74a1027311371a57258eba1bc908e050f5702277'
+source=("$pkgname::git+https://github.com/edicl/flexi-streams#commit=$_commit")
+b2sums=('SKIP')
+
+pkgver() {
+ cd "$pkgname"
+
+ git describe --tags | sed -e 's/^v//' -e 's/-/.r/' -e 's/-/./g'
+}
+
+prepare() {
+ cd "$pkgname"
+
+ sed -n '/;;; Copyright/,/;;; SOFTWARE/p' flexi-streams.asd \
+ | sed 's/;;; //' \
+ > LICENSE
+}
+
+package() {
+ cd "$pkgname"
+
+ # create directories
+ install -vd \
+ "$pkgdir/usr/share/common-lisp/source/$_pkgname" \
+ "$pkgdir/usr/share/common-lisp/systems"
+
+ # library
+ cp -vr test ./*.{lisp,asd} "$pkgdir/usr/share/common-lisp/source/$_pkgname"
+ pushd "$pkgdir/usr/share/common-lisp/systems"
+ ln -s "../source/$_pkgname/$_pkgname.asd" .
+ ln -s "../source/$_pkgname/$_pkgname-test.asd" .
+ popd
+
+ # documentation
+ install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" README.md docs/index.html
+
+ # license
+ install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
+}
More information about the arch-commits
mailing list