[arch-commits] Commit in cl-ppcre/repos (community-any community-any/PKGBUILD)

[George Rawlinson]

    Date: Wednesday, May 11, 2022 @ 03:40:21
  Author: grawlinson
Revision: 1198273

archrelease: copy trunk to community-any

Added:
  cl-ppcre/repos/community-any/
  cl-ppcre/repos/community-any/PKGBUILD
    (from rev 1198272, cl-ppcre/trunk/PKGBUILD)

----------+
 PKGBUILD |   43 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

Copied: cl-ppcre/repos/community-any/PKGBUILD (from rev 1198272, cl-ppcre/trunk/PKGBUILD)
===================================================================
--- community-any/PKGBUILD	                        (rev 0)
+++ community-any/PKGBUILD	2022-05-11 03:40:21 UTC (rev 1198273)
@@ -0,0 +1,43 @@
+# Maintainer: George Rawlinson <grawlinson at archlinux.org>
+
+pkgname=cl-ppcre
+pkgver=2.1.1.r3.gb4056c5
+pkgrel=1
+pkgdesc='Perl-compatible portable regexp library for Common Lisp'
+arch=('any')
+url='https://edicl.github.io/cl-ppcre/'
+license=('BSD')
+depends=('common-lisp' 'cl-asdf' 'cl-unicode')
+makedepends=('git' 'sbcl')
+_commit='b4056c5aecd9304e80abced0ef9c89cd66ecfb5e'
+source=("$pkgname::git+https://github.com/edicl/cl-ppcre#commit=$_commit")
+b2sums=('SKIP')
+
+pkgver() {
+  cd "$pkgname"
+
+  git describe --tags | sed -e 's/^v//' -e 's/-/.r/' -e 's/-/./g'
+}
+
+package() {
+  cd "$pkgname"
+
+  # create directories
+  install -vd \
+    "$pkgdir/usr/share/common-lisp/source/$pkgname" \
+    "$pkgdir/usr/share/common-lisp/systems"
+
+  # library
+  cp -vr test cl-ppcre-unicode ./*.{lisp,asd} "$pkgname.asd" "$pkgdir/usr/share/common-lisp/source/$pkgname"
+
+  pushd "$pkgdir/usr/share/common-lisp/systems"
+  ln -s "../source/$pkgname/$pkgname.asd" .
+  ln -s "../source/$pkgname/$pkgname-unicode.asd" .
+  popd
+
+  # documentation
+  install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" README.md docs/index.html
+
+  # license
+  install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
+}