[arch-commits] Commit in seatd/repos (3 files)

[Brett Cornwall]

    Date: Wednesday, May 11, 2022 @ 05:18:14
  Author: ainola
Revision: 1198279

archrelease: copy trunk to community-testing-x86_64

Added:
  seatd/repos/community-testing-x86_64/
  seatd/repos/community-testing-x86_64/PKGBUILD
    (from rev 1198278, seatd/trunk/PKGBUILD)
  seatd/repos/community-testing-x86_64/sysuser.conf
    (from rev 1198278, seatd/trunk/sysuser.conf)

--------------+
 PKGBUILD     |   53 +++++++++++++++++++++++++++++++++++++++++++++++++++++
 sysuser.conf |    1 +
 2 files changed, 54 insertions(+)

Copied: seatd/repos/community-testing-x86_64/PKGBUILD (from rev 1198278, seatd/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2022-05-11 05:18:14 UTC (rev 1198279)
@@ -0,0 +1,53 @@
+# Maintainer: Brett Cornwall <ainola at archlinux.org>
+
+pkgname=seatd
+pkgver=0.6.4
+pkgrel=2
+pkgdesc="A minimal seat management daemon, and a universal seat management library"
+arch=(x86_64)
+url="https://sr.ht/~kennylevinsen/seatd/"
+license=('MIT')
+provides=("libseat.so")
+replaces=("libseat")
+makedepends=(
+    'meson'
+    'ninja'
+    'scdoc'
+    'systemd'
+)
+depends=(
+    'systemd-libs'
+)
+options=(debug)
+source=(
+    "$pkgname-$pkgver.tar.gz::https://git.sr.ht/~kennylevinsen/seatd/archive/$pkgver.tar.gz"
+    "sysuser.conf"
+)
+sha256sums=('3d4ac288114219ba7721239cafee7bfbeb7cf8e1e7fd653602a369e4ad050bd8'
+            'e833292adf5da25b5258a5209c258f0e4c12e1d6fe81cf228fd0cfb575080d78')
+build() {
+    mkdir build
+    meson --prefix=/usr \
+          --buildtype=plain \
+          -Dexamples="disabled" \
+          -Dserver="enabled" \
+          -Dlibseat-logind="systemd" \
+          -Dman-pages="enabled" \
+          "seatd-$pkgver" \
+          build
+    ninja -C build
+}
+
+check() {
+    ninja -C build test
+}
+
+package() {
+    DESTDIR="$pkgdir/" ninja -C build install
+    install -Dm644 "seatd-$pkgver/LICENSE" -t "$pkgdir/usr/share/licenses/$pkgname/"
+
+    # Allow users in the "seat" group to access seatd
+    install -Dm644 "seatd-$pkgver/contrib/systemd/seatd.service" \
+            -t "$pkgdir/usr/lib/systemd/system/"
+    install -Dm644 "sysuser.conf" "$pkgdir/usr/lib/sysusers.d/seatd.conf"
+}

Copied: seatd/repos/community-testing-x86_64/sysuser.conf (from rev 1198278, seatd/trunk/sysuser.conf)
===================================================================
--- community-testing-x86_64/sysuser.conf	                        (rev 0)
+++ community-testing-x86_64/sysuser.conf	2022-05-11 05:18:14 UTC (rev 1198279)
@@ -0,0 +1 @@
+g seat - -