[arch-commits] Commit in haskell-hopenpgp/repos (2 files)

[Felix Yan]

    Date: Thursday, May 12, 2022 @ 14:21:35
  Author: felixonmars
Revision: 1199602

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-hopenpgp/repos/community-staging-x86_64/
  haskell-hopenpgp/repos/community-staging-x86_64/PKGBUILD
    (from rev 1199601, haskell-hopenpgp/trunk/PKGBUILD)

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Copied: haskell-hopenpgp/repos/community-staging-x86_64/PKGBUILD (from rev 1199601, haskell-hopenpgp/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-05-12 14:21:35 UTC (rev 1199602)
@@ -0,0 +1,52 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=hOpenPGP
+pkgname=haskell-hopenpgp
+pkgver=2.9.7
+pkgrel=55
+pkgdesc="Native Haskell implementation of OpenPGP (RFC4880)"
+url="http://floss.scru.org/hOpenPGP/"
+license=('MIT')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-asn1-encoding' 'haskell-attoparsec'
+         'haskell-base16-bytestring' 'haskell-bifunctors' 'haskell-bz2' 'haskell-binary-conduit'
+         'haskell-conduit' 'haskell-conduit-extra' 'haskell-cryptonite'
+         'haskell-crypto-cipher-types' 'haskell-errors' 'haskell-hashable'
+         'haskell-incremental-parser' 'haskell-ixset-typed' 'haskell-lens' 'haskell-memory'
+         'haskell-monad-loops' 'haskell-nettle' 'haskell-network-uri'
+         'haskell-openpgp-asciiarmor' 'haskell-prettyprinter' 'haskell-resourcet' 'haskell-split'
+         'haskell-time-locale-compat' 'haskell-unliftio-core' 'haskell-unordered-containers'
+         'haskell-zlib')
+makedepends=('ghc' 'haskell-quickcheck' 'haskell-quickcheck-instances' 'haskell-tasty'
+             'haskell-tasty-hunit' 'haskell-tasty-quickcheck')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('c8589b9bbbc8e211594946a1cad81bda51375f388f7252fab8d87c64ae2cc62e3fb038b405329fee8e7887335b17cf0f82014dc31c60ca1cf34c808d4f0e9b26')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm \
+            -fnetwork-uri
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}