[arch-commits] Commit in (3 files)

[Antonio Rojas]

    Date: Thursday, May 12, 2022 @ 22:33:47
  Author: arojas
Revision: 1199823

Add as pithigra dependency

Added:
  python-ipycanvas/
  python-ipycanvas/trunk/
  python-ipycanvas/trunk/PKGBUILD

----------+
 PKGBUILD |   31 +++++++++++++++++++++++++++++++
 1 file changed, 31 insertions(+)

Added: python-ipycanvas/trunk/PKGBUILD
===================================================================
--- python-ipycanvas/trunk/PKGBUILD	                        (rev 0)
+++ python-ipycanvas/trunk/PKGBUILD	2022-05-12 22:33:47 UTC (rev 1199823)
@@ -0,0 +1,31 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+
+pkgname=python-ipycanvas
+_pyname=${pkgname#python-}
+pkgver=0.12.0
+pkgrel=1
+pkgdesc="Interactive widgets library exposing the browser's Canvas API"
+url='https://github.com/martinRenou/ipycanvas'
+arch=(any)
+license=(BSD)
+source=(https://files.pythonhosted.org/packages/source/${_pyname::1}/$_pyname/$_pyname-$pkgver.tar.gz)
+depends=(python-ipywidgets python-pillow python-numpy)
+makedepends=(python-build python-installer python-jupyter_packaging jupyterlab)
+sha256sums=('3984339cef0c15674e347dd65ffb0cd1edc62e37869cbb5efea46f3259e976f3')
+
+prepare() {
+  cd $_pyname-$pkgver
+  sed -e 's|jupyter_packaging~=0.7.0|jupyter_packaging|' -i pyproject.toml # Drop version constraint
+}
+
+build() {
+  cd $_pyname-$pkgver
+  python -m build --wheel --no-isolation
+}
+
+package() {
+  cd $_pyname-$pkgver
+  python -m installer --destdir="$pkgdir" dist/*.whl
+  install -Dm644 LICENSE.txt "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+  mv "$pkgdir"/{usr/,}etc
+}