[arch-commits] Commit in pandoc-crossref/repos (2 files)

Felix Yan felixonmars at gemini.archlinux.org
Fri May 13 03:32:31 UTC 2022


    Date: Friday, May 13, 2022 @ 03:32:30
  Author: felixonmars
Revision: 1200005

archrelease: copy trunk to community-staging-x86_64

Added:
  pandoc-crossref/repos/community-staging-x86_64/
  pandoc-crossref/repos/community-staging-x86_64/PKGBUILD
    (from rev 1200004, pandoc-crossref/trunk/PKGBUILD)

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Copied: pandoc-crossref/repos/community-staging-x86_64/PKGBUILD (from rev 1200004, pandoc-crossref/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-05-13 03:32:30 UTC (rev 1200005)
@@ -0,0 +1,47 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Maintainer: Caleb Maclennan <caleb at alerque.com>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+pkgname=pandoc-crossref
+pkgver=0.3.12.2
+pkgrel=92
+pkgdesc="Pandoc filter for cross-references"
+url="https://hackage.haskell.org/package/${pkgname}"
+license=("GPL2")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-data-default' 'haskell-gitrev' 'haskell-microlens'
+         'haskell-microlens-mtl' 'haskell-microlens-th' 'haskell-open-browser'
+         'haskell-optparse-applicative' 'pandoc' 'haskell-pandoc-types' 'haskell-roman-numerals'
+         'haskell-syb' 'haskell-utility-ht')
+makedepends=('ghc' 'haskell-hspec')
+conflicts=('haskell-pandoc-crossref')
+replaces=('haskell-pandoc-crossref')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/lierdakil/pandoc-crossref/archive/v$pkgver.tar.gz")
+sha512sums=('44223954ee459a3215ab162e6098a1bd6bce0c02d09aee72cebbe26d977f3cce90e1cd90c01628df68c4d1f0452694eb5b19ebee6ca30e4f8e8e34d0040b4670')
+
+build() {
+    cd $pkgname-$pkgver
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname --enable-tests --datasubdir=$pkgname \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm \
+        -f-enable_flaky_tests
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $pkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $pkgname-$pkgver
+
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}



More information about the arch-commits mailing list