[arch-commits] Commit in qgnomeplatform (3 files)

[Antonio Rojas]

    Date: Friday, May 13, 2022 @ 22:02:50
  Author: arojas
Revision: 1203021

archrelease: copy trunk to community-x86_64

Added:
  qgnomeplatform/repos/
  qgnomeplatform/repos/community-x86_64/
  qgnomeplatform/repos/community-x86_64/PKGBUILD
    (from rev 1203020, qgnomeplatform/trunk/PKGBUILD)

----------+
 PKGBUILD |   46 ++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

Copied: qgnomeplatform/repos/community-x86_64/PKGBUILD (from rev 1203020, qgnomeplatform/trunk/PKGBUILD)
===================================================================
--- repos/community-x86_64/PKGBUILD	                        (rev 0)
+++ repos/community-x86_64/PKGBUILD	2022-05-13 22:02:50 UTC (rev 1203021)
@@ -0,0 +1,46 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: j.r <j.r at jugendhacker.de>
+# Contributor: Jonathan Chasteen <jonathan dot chasteen at live dot com>
+# Contributor: Mohammadreza Abdollahzadeh <morealaz at gmail dot com>
+# Contributor: aimileus <me at aimileus dot nl>
+# Contributor: spider-mario <spidermario at free.fr>
+
+pkgbase=qgnomeplatform
+_pkgname=QGnomePlatform
+pkgname=(qgnomeplatform-qt5 qgnomeplatform-qt6)
+pkgver=0.8.4
+pkgrel=2
+pkgdesc='QPlatformTheme for a better Qt application inclusion in GNOME'
+arch=(x86_64)
+url='https://github.com/FedoraQt/QGnomePlatform'
+license=(LGPL2.1)
+makedepends=(cmake gtk3 qt5-wayland qt6-wayland adwaita-qt5 adwaita-qt6)
+source=(https://github.com/FedoraQt/QGnomePlatform/archive/$pkgver/$_pkgname-$pkgver.tar.gz)
+sha256sums=('c648331f47b095d90594fc986a6c0bc885b846e0e9f5c10b6a1ba6a58d004686')
+
+build() {
+  cmake -B build-qt5 -S $_pkgname-$pkgver \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DUSE_QT6=OFF
+  cmake --build build-qt5
+
+  cmake -B build-qt6 -S $_pkgname-$pkgver \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DUSE_QT6=ON
+  cmake --build build-qt6
+}
+
+package_qgnomeplatform-qt5() {
+  pkgdesc='QPlatformTheme for a better Qt5 application inclusion in GNOME'
+  depends=(gtk3 qt5-wayland adwaita-qt5)
+  replaces=(qgnomeplatform)
+
+  DESTDIR="$pkgdir" cmake --install build-qt5
+}
+
+package_qgnomeplatform-qt6() {
+  pkgdesc='QPlatformTheme for a better Qt6 application inclusion in GNOME'
+  depends=(gtk3 qt6-wayland adwaita-qt6)
+
+  DESTDIR="$pkgdir" cmake --install build-qt6
+}