[arch-commits] Commit in graphicsmagick/repos (staging-x86_64 staging-x86_64/PKGBUILD)

[Antonio Rojas]

    Date: Saturday, May 14, 2022 @ 08:22:51
  Author: arojas
Revision: 445446

archrelease: copy trunk to staging-x86_64

Added:
  graphicsmagick/repos/staging-x86_64/
  graphicsmagick/repos/staging-x86_64/PKGBUILD
    (from rev 445445, graphicsmagick/trunk/PKGBUILD)

----------+
 PKGBUILD |   63 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 63 insertions(+)

Copied: graphicsmagick/repos/staging-x86_64/PKGBUILD (from rev 445445, graphicsmagick/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2022-05-14 08:22:51 UTC (rev 445446)
@@ -0,0 +1,63 @@
+# Maintainer: Ronald van Haren <ronald.archlinux.org>
+# Maintainer: Gaetan Bisson <bisson at archlinux.org>
+# Contributor: Jaroslav Lichtblau <dragonlord at aur.archlinux.org>
+# Contributor: Anton Leontiev <bunder at t-25.ru>
+
+pkgname=graphicsmagick
+pkgver=1.3.38
+pkgrel=2
+pkgdesc='Image processing system'
+url='http://www.graphicsmagick.org/'
+arch=('x86_64')
+license=('MIT')
+optdepends=('jasper: jp2 module'
+            'libwmf: wmf module'
+            'libxml2: msl, svg, url modules'
+            'ghostscript: pdf, ps modules')
+makedepends=('perl' 'jasper' 'libwmf' 'libxml2')
+depends=('freetype2' 'libxext' 'libsm' 'lcms2' 'libltdl' 'bzip2' 'xz'
+         'libpng' 'libtiff' 'libwebp')
+source=("https://downloads.sourceforge.net/project/${pkgname}/${pkgname}/${pkgver}/GraphicsMagick-${pkgver}.tar.xz")
+sha256sums=('d60cd9db59351d2b9cb19beb443170acaa28f073d13d258f67b3627635e32675')
+
+options=('!emptydirs' 'libtool')
+
+prepare() {
+	cd "${srcdir}/GraphicsMagick-${pkgver}"
+	sed -e "s:freetype_config='':freetype_config='/usr/bin/pkg-config freetype2':g" -i configure
+}
+
+build() {
+	cd "${srcdir}/GraphicsMagick-${pkgver}"
+	./configure \
+		--prefix=/usr \
+		--enable-shared \
+		--with-modules \
+		--with-perl \
+		--with-quantum-depth=16 \
+		--with-threads
+	make
+}
+
+package() {
+	cd "${srcdir}/GraphicsMagick-${pkgver}"
+
+	make DESTDIR="${pkgdir}" install
+
+	# Install MIT license
+	install -Dm644 "Copyright.txt" "${pkgdir}/usr/share/licenses/${pkgname}/Copyright.txt"
+
+	# Install perl bindings
+	# The patching was introduced in order to build perl module without installing package itself and
+	# not to introduce unnecessary path into LD_RUN_PATH
+	cd PerlMagick
+	sed -i -e "s:'LDDLFLAGS'  => \"\(.*\)\":'LDDLFLAGS'  => \"-L${pkgdir}/usr/lib \1\":" Makefile.PL
+	perl Makefile.PL INSTALLDIRS=vendor PREFIX=/usr DESTDIR="${pkgdir}"
+	sed -i -e "s/LDLOADLIBS =/LDLOADLIBS = -lGraphicsMagick/" Makefile
+	make
+	make install
+
+	# Remove perllocal.pod and .packlist
+	rm -r "${pkgdir}"/usr/lib/perl5/*/core_perl
+	rm "${pkgdir}"/usr/lib/perl5/*/vendor_perl/auto/Graphics/Magick/.packlist
+}