[arch-commits] Commit in extra-cmake-modules/repos (testing-any testing-any/PKGBUILD)

[Antonio Rojas]

    Date: Saturday, May 14, 2022 @ 10:55:49
  Author: arojas
Revision: 445465

archrelease: copy trunk to testing-any

Added:
  extra-cmake-modules/repos/testing-any/
  extra-cmake-modules/repos/testing-any/PKGBUILD
    (from rev 445464, extra-cmake-modules/trunk/PKGBUILD)

----------+
 PKGBUILD |   33 +++++++++++++++++++++++++++++++++
 1 file changed, 33 insertions(+)

Copied: extra-cmake-modules/repos/testing-any/PKGBUILD (from rev 445464, extra-cmake-modules/trunk/PKGBUILD)
===================================================================
--- testing-any/PKGBUILD	                        (rev 0)
+++ testing-any/PKGBUILD	2022-05-14 10:55:49 UTC (rev 445465)
@@ -0,0 +1,33 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+
+pkgname=extra-cmake-modules
+pkgver=5.94.0
+pkgrel=1
+pkgdesc='Extra modules and scripts for CMake'
+arch=(any)
+url='https://community.kde.org/Frameworks'
+license=(LGPL)
+depends=(cmake)
+makedepends=(python-sphinx python-requests qt5-tools)
+optdepends=('python-pyxdg: to generate fastlane metadata for Android apps'
+            'python-requests: to generate fastlane metadata for Android apps'
+            'python-yaml: to generate fastlane metadata for Android apps')
+groups=(kf5)
+source=(https://download.kde.org/stable/frameworks/${pkgver%.*}/$pkgname-$pkgver.tar.xz{,.sig})
+sha256sums=('23548a8ce2b998cfa675fc00112bf93914ee25194f0bfdf832d283c8d678d279'
+            'SKIP')
+validpgpkeys=(53E6B47B45CEA3E0D5B7457758D0EE648A48B3BB) # David Faure <faure at kde.org>
+
+build() {
+  cmake -B build -S $pkgname-$pkgver \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DBUILD_HTML_DOCS=ON \
+    -DBUILD_QTHELP_DOCS=ON
+  cmake --build build
+}
+
+package() {
+  DESTDIR="$pkgdir" cmake --install build
+}