[arch-commits] Commit in oxygen-icons/repos (testing-any testing-any/PKGBUILD)
Antonio Rojas
arojas at gemini.archlinux.org
Sat May 14 11:07:07 UTC 2022
Date: Saturday, May 14, 2022 @ 11:07:07
Author: arojas
Revision: 445536
archrelease: copy trunk to testing-any
Added:
oxygen-icons/repos/testing-any/
oxygen-icons/repos/testing-any/PKGBUILD
(from rev 445535, oxygen-icons/trunk/PKGBUILD)
----------+
PKGBUILD | 38 ++++++++++++++++++++++++++++++++++++++
1 file changed, 38 insertions(+)
Copied: oxygen-icons/repos/testing-any/PKGBUILD (from rev 445535, oxygen-icons/trunk/PKGBUILD)
===================================================================
--- testing-any/PKGBUILD (rev 0)
+++ testing-any/PKGBUILD 2022-05-14 11:07:07 UTC (rev 445536)
@@ -0,0 +1,38 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+# Contributor: Pierre Schmitz <pierre at archlinux.de>
+
+pkgbase=oxygen-icons
+pkgname=(oxygen-icons oxygen-icons-svg)
+pkgver=5.94.0
+epoch=1
+pkgrel=1
+pkgdesc='The Oxygen Icon Theme'
+arch=(any)
+url='https://community.kde.org/Frameworks'
+license=(LGPL)
+makedepends=(extra-cmake-modules qt5-base)
+source=(https://download.kde.org/stable/frameworks/${pkgver%.*}/${pkgbase}5-$pkgver.tar.xz{,.sig})
+sha256sums=('203d9dbc3fb783c8c31c3d3d59624e31b502a50beea31505dcc56d8c33fcd1d0'
+ 'SKIP')
+validpgpkeys=(53E6B47B45CEA3E0D5B7457758D0EE648A48B3BB) # David Faure <faure at kde.org>
+
+build() {
+ cmake -B build -S ${pkgbase}5-$pkgver
+ cmake --build build
+}
+
+package_oxygen-icons() {
+ groups=(kf5)
+
+ DESTDIR="$pkgdir" cmake --install build
+}
+
+package_oxygen-icons-svg() {
+ pkgdesc='The Oxygen Icon Theme (Scalable Vector Graphics)'
+
+ cd ${pkgbase}5-$pkgver
+ find scalable -type f ! -name '*.sh' -exec \
+ install -D -m644 "{}" "$pkgdir"/usr/share/icons/oxygen/{} \;
+}
More information about the arch-commits
mailing list