[arch-commits] Commit in haskell-incremental-parser/repos (2 files)

[Felix Yan]

    Date: Saturday, May 14, 2022 @ 14:46:00
  Author: felixonmars
Revision: 1204947

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-incremental-parser/repos/community-staging-x86_64/
  haskell-incremental-parser/repos/community-staging-x86_64/PKGBUILD
    (from rev 1204946, haskell-incremental-parser/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: haskell-incremental-parser/repos/community-staging-x86_64/PKGBUILD (from rev 1204946, haskell-incremental-parser/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-05-14 14:46:00 UTC (rev 1204947)
@@ -0,0 +1,44 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Thomas Dziedzic <gostrc at gmail.com>
+
+_hkgname=incremental-parser
+pkgname=haskell-incremental-parser
+pkgver=0.5.0.3
+pkgrel=19
+pkgdesc="Generic parser library capable of providing partial results from partial input."
+url="https://hackage.haskell.org/package/${_hkgname}"
+license=('GPL')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-input-parsers' 'haskell-monoid-subclasses' 'haskell-parsers'
+         'haskell-rank2classes')
+makedepends=('ghc' 'haskell-quickcheck' 'haskell-checkers' 'haskell-tasty'
+             'haskell-tasty-quickcheck')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('e0e7d47e1421b97dc999c8a5a501f1c3318c2b9969e5f8db256f79b2f0e2bcbd90a4bde8b33a3e54d9c202ba49198af84a172ed5c169a7f55076c0e62a51ee15')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE.txt"
+}