[arch-commits] Commit in haskell-rebase/repos (2 files)

[Felix Yan]

    Date: Sunday, May 15, 2022 @ 06:26:12
  Author: felixonmars
Revision: 1207087

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-rebase/repos/community-staging-x86_64/
  haskell-rebase/repos/community-staging-x86_64/PKGBUILD
    (from rev 1207086, haskell-rebase/trunk/PKGBUILD)

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Copied: haskell-rebase/repos/community-staging-x86_64/PKGBUILD (from rev 1207086, haskell-rebase/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-05-15 06:26:12 UTC (rev 1207087)
@@ -0,0 +1,47 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=rebase
+pkgname=haskell-rebase
+pkgver=1.15.0.3
+pkgrel=16
+pkgdesc='A more progressive alternative to the "base" package'
+url="https://github.com/nikita-volkov/rebase"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-bifunctors' 'haskell-contravariant' 'haskell-comonad' 'haskell-dlist'
+         'haskell-either' 'haskell-groups' 'haskell-hashable' 'haskell-invariant'
+         'haskell-profunctors' 'haskell-scientific' 'haskell-selective' 'haskell-semigroupoids'
+         'haskell-time-compat' 'haskell-unordered-containers' 'haskell-uuid-types' 'haskell-vector'
+         'haskell-vector-instances' 'haskell-void')
+makedepends=('ghc' 'uusi')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('46c5790ba0bcf39b17a98eb32e6c5f68125abf9d20f51b6c3fa4fab665790eb1148878631e1e38677f53e1d81d52a1a96db18a8aec6e0eefbdacdd611340067a')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    gen-setup
+}
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}