[arch-commits] Commit in hdf5/repos (2 files)

[Bruno Pagani]

    Date: Sunday, May 15, 2022 @ 20:20:02
  Author: archange
Revision: 1207490

archrelease: copy trunk to community-staging-x86_64

Added:
  hdf5/repos/community-staging-x86_64/
  hdf5/repos/community-staging-x86_64/PKGBUILD
    (from rev 1207489, hdf5/trunk/PKGBUILD)

----------+
 PKGBUILD |   74 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 74 insertions(+)

Copied: hdf5/repos/community-staging-x86_64/PKGBUILD (from rev 1207489, hdf5/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-05-15 20:20:02 UTC (rev 1207490)
@@ -0,0 +1,74 @@
+# Maintainer: Ronald van Haren <ronald.archlinux.org>
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+# Contributor: Stefan Husmann <stefan-husmann at t-online.de>
+# Contributor: damir <damir at archlinux.org>
+# Contributor: Tom K <tomk at runbox.com>
+
+pkgname=hdf5
+pkgver=1.12.2
+pkgrel=1
+pkgdesc="General purpose library and file format for storing scientific data"
+arch=(x86_64)
+url="https://www.hdfgroup.org/hdf5"
+license=(custom)
+depends=(zlib libaec bash)
+makedepends=(cmake time gcc-fortran java-environment)
+replaces=(hdf5-java)
+provides=(hdf5-java)
+source=(https://support.hdfgroup.org/ftp/HDF5/releases/${pkgname}-${pkgver:0:4}/${pkgname}-${pkgver/_/-}/src/${pkgname}-${pkgver/_/-}.tar.bz2)
+sha256sums=('1a88bbe36213a2cea0c8397201a459643e7155c9dc91e062675b3fb07ee38afe')
+
+build() {
+    # Crazy workaround: run CMake to generate pkg-config file
+    #cmake -B build -S ${pkgname}-${pkgver/_/-} \
+    mkdir -p build && cd build
+    cmake ../${pkgname}-${pkgver/_/-} \
+        -DCMAKE_INSTALL_PREFIX=/usr \
+        -DBUILD_STATIC_LIBS=OFF \
+        -DCMAKE_BUILD_TYPE=Release \
+        -DHDF5_BUILD_HL_LIB=ON \
+        -DHDF5_BUILD_CPP_LIB=ON \
+        -DHDF5_BUILD_FORTRAN=ON \
+        -DHDF5_BUILD_JAVA=ON \
+        -DHDF5_ENABLE_Z_LIB_SUPPORT=ON \
+        -DHDF5_ENABLE_SZIP_SUPPORT=ON \
+        -DHDF5_ENABLE_SZIP_ENCODING=ON \
+        -DUSE_LIBAEC=ON
+    # But don’t build with it, it’s quite broken
+    cd ../${pkgname}-${pkgver/_/-}
+    ./configure \
+        --prefix=/usr \
+        --docdir=/usr/share/doc/hdf5/ \
+        --with-examplesdir=/usr/share/doc/hdf5/examples/ \
+        --disable-static \
+        --disable-sharedlib-rpath \
+        --enable-build-mode=production \
+        --enable-hl \
+        --enable-cxx \
+        --enable-fortran \
+        --enable-java \
+        --with-pic \
+        --with-zlib \
+        --with-szlib
+    make
+}
+
+check() {
+    cd ${pkgname}-${pkgver/_/-}
+    # Without this, checks are failing with messages like “error while loading shared libraries: libhdf5.so.101: cannot open shared object file: No such file or directory”
+    export LD_LIBRARY_PATH="${srcdir}"/${pkgname}-${pkgver/_/-}/src/.libs/
+    export LD_LIBRARY_PATH="$LD_LIBRARY_PATH":"${srcdir}"/${pkgname}-${pkgver/_/-}/c++/src/.libs/
+    export LD_LIBRARY_PATH="$LD_LIBRARY_PATH":"${srcdir}"/${pkgname}-${pkgver/_/-}/fortran/src/.libs/
+    export LD_LIBRARY_PATH="$LD_LIBRARY_PATH":"${srcdir}"/${pkgname}-${pkgver/_/-}/hl/src/.libs/
+    export LD_LIBRARY_PATH="$LD_LIBRARY_PATH":"${srcdir}"/${pkgname}-${pkgver/_/-}/hl/c++/src/.libs/
+    export LD_LIBRARY_PATH="$LD_LIBRARY_PATH":"${srcdir}"/${pkgname}-${pkgver/_/-}/hl/fortran/src/.libs/
+    make check
+}
+
+package() {
+    cd ${pkgname}-${pkgver/_/-}
+    make DESTDIR="${pkgdir}" install
+    install -Dm644 COPYING -t "${pkgdir}"/usr/share/licenses/${pkgname}
+    # Install pkg-config files from CMake tree
+    install -Dm644 ../build/CMakeFiles/hdf5{,_hl}{,_cpp,_fortran}.pc -t "${pkgdir}"/usr/lib/pkgconfig/
+}