[arch-commits] Commit in jami-daemon/repos (2 files)

[Bruno Pagani]

    Date: Sunday, May 15, 2022 @ 17:03:32
  Author: archange
Revision: 1207475

archrelease: copy trunk to community-testing-x86_64

Added:
  jami-daemon/repos/community-testing-x86_64/
  jami-daemon/repos/community-testing-x86_64/PKGBUILD
    (from rev 1207474, jami-daemon/trunk/PKGBUILD)

----------+
 PKGBUILD |   60 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 60 insertions(+)

Copied: jami-daemon/repos/community-testing-x86_64/PKGBUILD (from rev 1207474, jami-daemon/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2022-05-15 17:03:32 UTC (rev 1207475)
@@ -0,0 +1,60 @@
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+# Contributor: Baptiste Jonglez <baptiste--aur at jonglez dot org>
+
+pkgname=jami-daemon
+pkgver=20220511
+pkgrel=1
+pkgdesc="Free and universal communication platform which preserves the users’ privacy and freedoms (daemon component)"
+arch=(x86_64)
+url="https://jami.net"
+license=(GPL3)
+groups=(jami)
+depends=(glibc opendht gnutls nettle libgit2 libsecp256k1 ffmpeg speexdsp
+         fmt yaml-cpp jsoncpp zlib dbus-c++ alsa-lib libpulse jack
+         libupnp libnatpmp openssl webrtc-audio-processing systemd-libs
+         libarchive)
+# portaudio needs a not-yet-upstream patch https://git.jami.net/savoirfairelinux/jami-daemon/-/issues/650
+makedepends=(git cmake perl asio msgpack-c msgpack-cxx restinio systemd meson)
+checkdepends=(cppunit)
+_commit=35a0fcdeb8b4c14f21e8aea87fe4892c8566fef4
+_pjprojectver=e1f389d0b905011e0cb62cbdf7a8b37fc1bcde1a
+source=(git+https://git.jami.net/savoirfairelinux/${pkgname}.git#commit=${_commit}
+        https://github.com/savoirfairelinux/pjproject/archive/${_pjprojectver}/pjproject-${_pjprojectver}.tar.gz)
+noextract=(pjproject-${_pjprojectver}.tar.gz)
+sha512sums=(SKIP a1ed0519ddf8dc91f47042497530cbcb1c8736506d0c2b677751a3368c0a202952ff563946664705dbf5806bed8ade784885db62f8278a204f516a4e60917b1e)
+
+pkgver() {
+  cd ${pkgname}
+  TZ=UTC git show -s --pretty=%cd --date=format-local:%Y%m%d HEAD
+}
+
+prepare() {
+  cd ${pkgname}
+  cp ../pjproject-${_pjprojectver}.tar.gz contrib/tarballs
+  mkdir contrib/native
+}
+
+build() {
+  cd ${pkgname}/contrib/native
+  export CXXFLAGS+=' -fpermissive'
+  ../bootstrap \
+      --disable-downloads \
+      --disable-all \
+      --enable-pjproject
+  make DEPS_pjproject=
+
+  cd "${srcdir}"
+  arch-meson ${pkgname} build -D interfaces=library,dbus -D opensl=disabled -D portaudio=disabled \
+                              $( ((CHECKFUNC)) && echo -D tests=true) \
+                              -D pkg_config_path="${PWD}/${pkgname}/contrib/$(cc -dumpmachine)/lib/pkgconfig"
+  meson compile -C build
+}
+
+#check() {
+# https://git.jami.net/savoirfairelinux/jami-daemon/-/issues/649
+#  meson test -C build --print-errorlogs
+#}
+
+package() {
+  meson install -C build --destdir "${pkgdir}"
+}