[arch-commits] Commit in opencv/repos (3 files)

Antonio Rojas arojas at gemini.archlinux.org
Sun May 15 22:06:54 UTC 2022


    Date: Sunday, May 15, 2022 @ 22:06:54
  Author: arojas
Revision: 445853

archrelease: copy trunk to staging-x86_64

Added:
  opencv/repos/staging-x86_64/
  opencv/repos/staging-x86_64/PKGBUILD
    (from rev 445852, opencv/trunk/PKGBUILD)
  opencv/repos/staging-x86_64/vtk9.patch
    (from rev 445852, opencv/trunk/vtk9.patch)

------------+
 PKGBUILD   |  133 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 vtk9.patch |   36 +++++++++++++++
 2 files changed, 169 insertions(+)

Copied: opencv/repos/staging-x86_64/PKGBUILD (from rev 445852, opencv/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2022-05-15 22:06:54 UTC (rev 445853)
@@ -0,0 +1,133 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Ray Rashif <schiv at archlinux.org>
+# Contributor: Tobias Powalowski <tpowa at archlinux.org>
+
+pkgbase=opencv
+pkgname=(opencv opencv-samples python-opencv opencv-cuda)
+pkgver=4.5.5
+pkgrel=6
+pkgdesc='Open Source Computer Vision Library'
+arch=(x86_64)
+license=(BSD)
+url='https://opencv.org/'
+depends=(tbb openexr gst-plugins-base libdc1394 cblas lapack libgphoto2 openjpeg2 ffmpeg4.4 protobuf)
+makedepends=(cmake python-numpy python-setuptools mesa eigen hdf5 lapacke qt5-base vtk glew ant java-environment pugixml openmpi cudnn fmt)
+optdepends=('opencv-samples: samples'
+            'vtk: for the viz module'
+            'glew: for the viz module'
+            'qt5-base: for the HighGUI module'
+            'hdf5: for the HDF5 module'
+            'opencl-icd-loader: For coding with OpenCL'
+            'java-runtime: Java interface')
+source=(https://github.com/opencv/opencv/archive/$pkgver/$pkgname-$pkgver.tar.gz
+        https://github.com/opencv/opencv_contrib/archive/$pkgver/opencv_contrib-$pkgver.tar.gz
+        vtk9.patch)
+sha256sums=('a1cfdcf6619387ca9e232687504da996aaa9f7b5689986b8331ec02cb61d28ad'
+            'a97c2eaecf7a23c6dbd119a609c6d7fae903e5f9ff5f1fe678933e01c67a6c11'
+            'f35a2d4ea0d6212c7798659e59eda2cb0b5bc858360f7ce9c696c77d3029668e')
+
+prepare() {
+  patch -d $pkgname-$pkgver -p1 < vtk9.patch # Don't require all vtk optdepends
+}
+
+build() {
+  export JAVA_HOME="/usr/lib/jvm/default" PKG_CONFIG_PATH=/usr/lib/ffmpeg4.4/pkgconfig
+  # cmake's FindLAPACK doesn't add cblas to LAPACK_LIBRARIES, so we need to specify them manually
+  _opts="-DWITH_OPENCL=ON \
+         -DWITH_OPENGL=ON \
+         -DWITH_TBB=ON \
+         -DWITH_VULKAN=ON \
+         -DWITH_QT=ON \
+         -DBUILD_WITH_DEBUG_INFO=OFF \
+         -DBUILD_TESTS=OFF \
+         -DBUILD_PERF_TESTS=OFF \
+         -DBUILD_EXAMPLES=ON \
+         -DBUILD_PROTOBUF=OFF \
+         -DPROTOBUF_UPDATE_FILES=ON \
+         -DINSTALL_C_EXAMPLES=ON \
+         -DINSTALL_PYTHON_EXAMPLES=ON \
+         -DCMAKE_INSTALL_PREFIX=/usr \
+         -DCPU_BASELINE_DISABLE=SSE3 \
+         -DCPU_BASELINE_REQUIRE=SSE2 \
+         -DOPENCV_EXTRA_MODULES_PATH=$srcdir/opencv_contrib-$pkgver/modules \
+         -DOPENCV_SKIP_PYTHON_LOADER=ON \
+         -DLAPACK_LIBRARIES=/usr/lib/liblapack.so;/usr/lib/libblas.so;/usr/lib/libcblas.so \
+         -DLAPACK_CBLAS_H=/usr/include/cblas.h \
+         -DLAPACK_LAPACKE_H=/usr/include/lapacke.h \
+         -DOPENCV_GENERATE_PKGCONFIG=ON \
+         -DOPENCV_ENABLE_NONFREE=ON \
+         -DOPENCV_JNI_INSTALL_PATH=lib \
+         -DOPENCV_GENERATE_SETUPVARS=OFF \
+         -DEIGEN_INCLUDE_PATH=/usr/include/eigen3"
+ 
+  cmake -B build -S $pkgname-$pkgver $_opts
+  cmake --build build
+
+  CFLAGS="${CFLAGS} -fno-lto" CXXFLAGS="${CXXFLAGS} -fno-lto" LDFLAGS="${LDFLAGS} -fno-lto" \
+  cmake -B build-cuda -S $pkgname-$pkgver $_opts \
+    -DWITH_CUDA=ON \
+    -DWITH_CUDNN=ON
+  cmake --build build-cuda
+}
+
+package_opencv() {
+  DESTDIR="$pkgdir" cmake --install build
+
+  # install license file
+  install -Dm644 $pkgbase-$pkgver/LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname
+
+  # separate samples package
+  mv "$pkgdir"/usr/share/opencv4/samples "$srcdir"
+
+  # Add java symlinks expected by some binary blobs
+  ln -sr "$pkgdir"/usr/share/java/{opencv4/opencv-${pkgver//./},opencv}.jar
+  ln -sr "$pkgdir"/usr/lib/{libopencv_java${pkgver//./},libopencv_java}.so
+
+  # Split Python bindings
+  rm -r "$pkgdir"/usr/lib/python3*
+}
+
+package_opencv-samples() {
+  pkgdesc+=' (samples)'
+  depends=(opencv)
+  unset optdepends
+
+  mkdir -p "$pkgdir"/usr/share/opencv4
+  mv samples "$pkgdir"/usr/share/opencv4
+
+  # install license file
+  install -Dm644 $pkgbase-$pkgver/LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname
+}
+
+package_python-opencv() {
+  pkgdesc='Python bindings for OpenCV'
+  depends=(python-numpy opencv vtk glew qt5-base hdf5 jsoncpp openmpi pugixml fmt)
+  unset optdepends
+
+  DESTDIR="$pkgdir" cmake --install build/modules/python3
+
+  # install license file
+  install -Dm644 $pkgbase-$pkgver/LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname
+}
+
+package_opencv-cuda() {
+  pkgdesc+=' (with CUDA support)'
+  depends+=(cudnn)
+  conflicts=(opencv)
+  provides=(opencv=$pkgver)
+
+  DESTDIR="$pkgdir" cmake --install build-cuda
+
+  # install license file
+  install -Dm644 $pkgbase-$pkgver/LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname
+
+  # Split samples
+  rm -r "$pkgdir"/usr/share/opencv4/samples
+
+  # Add java symlinks expected by some binary blobs
+  ln -sr "$pkgdir"/usr/share/java/{opencv4/opencv-${pkgver//./},opencv}.jar
+  ln -sr "$pkgdir"/usr/lib/{libopencv_java${pkgver//./},libopencv_java}.so
+
+  # Split Python bindings
+  rm -r "$pkgdir"/usr/lib/python3*
+}

Copied: opencv/repos/staging-x86_64/vtk9.patch (from rev 445852, opencv/trunk/vtk9.patch)
===================================================================
--- staging-x86_64/vtk9.patch	                        (rev 0)
+++ staging-x86_64/vtk9.patch	2022-05-15 22:06:54 UTC (rev 445853)
@@ -0,0 +1,36 @@
+diff --git a/cmake/OpenCVDetectVTK.cmake b/cmake/OpenCVDetectVTK.cmake
+index 312fd41fe4..aeda80d47c 100644
+--- a/cmake/OpenCVDetectVTK.cmake
++++ b/cmake/OpenCVDetectVTK.cmake
+@@ -1,8 +1,5 @@
+ if(NOT VTK_FOUND)
+-  find_package(VTK QUIET NAMES vtk VTK)
+-  if(VTK_FOUND)
+-    if(NOT (VTK_VERSION VERSION_LESS "9.0.0") AND (VTK_VERSION VERSION_LESS "10.0.0")) # VTK 9.x
+-      find_package(VTK 9 QUIET NAMES vtk COMPONENTS
++  find_package(VTK 9 QUIET NAMES vtk COMPONENTS
+               FiltersExtraction
+               FiltersSources
+               FiltersTexture
+@@ -14,21 +11,6 @@ if(NOT VTK_FOUND)
+               RenderingLOD
+               RenderingOpenGL2
+               NO_MODULE)
+-    elseif(VTK_VERSION VERSION_GREATER "5") # VTK 6.x components
+-      find_package(VTK QUIET COMPONENTS vtkInteractionStyle vtkRenderingLOD vtkIOPLY vtkFiltersTexture vtkRenderingFreeType vtkIOExport NO_MODULE)
+-      IF(VTK_FOUND)
+-        IF(VTK_RENDERING_BACKEND) #in vtk 7, the rendering backend is exported as a var.
+-          find_package(VTK QUIET COMPONENTS vtkRendering${VTK_RENDERING_BACKEND} vtkInteractionStyle vtkRenderingLOD vtkIOPLY vtkFiltersTexture vtkRenderingFreeType vtkIOExport vtkIOGeometry NO_MODULE)
+-        ELSE(VTK_RENDERING_BACKEND)
+-          find_package(VTK QUIET COMPONENTS vtkRenderingOpenGL vtkInteractionStyle vtkRenderingLOD vtkIOPLY vtkFiltersTexture vtkRenderingFreeType vtkIOExport NO_MODULE)
+-        ENDIF(VTK_RENDERING_BACKEND)
+-      ENDIF(VTK_FOUND)
+-    elseif(VTK_VERSION VERSION_EQUAL "5") # VTK 5.x components
+-      find_package(VTK QUIET COMPONENTS vtkCommon NO_MODULE)
+-    else()
+-      set(VTK_FOUND FALSE)
+-    endif()
+-  endif()
+ endif()
+ 
+ if(NOT VTK_FOUND)



More information about the arch-commits mailing list