[arch-commits] Commit in blender/repos (4 files)
Sven-Hendrik Haase
svenstaro at gemini.archlinux.org
Mon May 16 01:11:31 UTC 2022
Date: Monday, May 16, 2022 @ 01:11:30
Author: svenstaro
Revision: 1207502
archrelease: copy trunk to community-staging-x86_64
Added:
blender/repos/community-staging-x86_64/
blender/repos/community-staging-x86_64/PKGBUILD
(from rev 1207501, blender/trunk/PKGBUILD)
blender/repos/community-staging-x86_64/force-draco1.patch
(from rev 1207501, blender/trunk/force-draco1.patch)
blender/repos/community-staging-x86_64/force-draco2.patch
(from rev 1207501, blender/trunk/force-draco2.patch)
--------------------+
PKGBUILD | 97 +++++++++++++++++++++++++++++++++++++++++++++++++++
force-draco1.patch | 15 +++++++
force-draco2.patch | 21 +++++++++++
3 files changed, 133 insertions(+)
Copied: blender/repos/community-staging-x86_64/PKGBUILD (from rev 1207501, blender/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD (rev 0)
+++ community-staging-x86_64/PKGBUILD 2022-05-16 01:11:30 UTC (rev 1207502)
@@ -0,0 +1,97 @@
+# Maintainer: Sven-Hendrik Haase <svenstaro at archlinux.org>
+# Contributor: John Sowiak <john at archlinux.org>
+# Contributor: tobias <tobias at archlinux.org>
+
+# For legal reasons, we can't separately package the Optix headers so we'll
+# just build the package against them. I checked with NVIDIA and this way is
+# fine with them.
+
+pkgname=blender
+pkgver=3.1.2
+pkgrel=3
+epoch=17
+pkgdesc="A fully integrated 3D graphics creation suite"
+arch=('x86_64')
+license=('GPL')
+url="https://www.blender.org"
+depends=('libpng' 'libtiff' 'openexr' 'python' 'desktop-file-utils' 'python-requests' 'potrace'
+ 'shared-mime-info' 'hicolor-icon-theme' 'xdg-utils' 'glew' 'openjpeg2' 'python-numpy'
+ 'freetype2' 'openal' 'ffmpeg' 'fftw' 'boost-libs' 'opencollada' 'alembic' 'openxr'
+ 'openimageio' 'libsndfile' 'jack' 'opencolorio' 'openshadinglanguage' 'openimagedenoise'
+ 'jemalloc' 'libspnav' 'ptex' 'opensubdiv' 'openvdb' 'log4cplus' 'sdl2' 'embree' 'libharu'
+ 'draco')
+makedepends=('cmake' 'boost' 'mesa' 'git' 'llvm' 'cuda' 'ninja')
+optdepends=('cuda: cycles renderer cuda support')
+options=(!strip)
+source=("git+https://git.blender.org/blender.git#tag=v$pkgver"
+ "git+https://git.blender.org/blender-addons.git"
+ "git+https://git.blender.org/blender-addons-contrib.git"
+ "git+https://git.blender.org/blender-translations.git"
+ "git+https://git.blender.org/blender-dev-tools.git"
+ https://developer.download.nvidia.com/redist/optix/v7.3/OptiX-7.3.0-Include.zip
+ force-draco1.patch
+ force-draco2.patch)
+sha512sums=('SKIP'
+ 'SKIP'
+ 'SKIP'
+ 'SKIP'
+ 'SKIP'
+ 'd842e989bf86f4ae932f8708f6340861de4ea33b21435cceeb9a5e3135ef2ddb671e19fe11c397bddbf85894ba312194eac5acc21cbec70607120c0bda0100ef'
+ 'e239da4f3906f1b54265435181cf770bae3d269c8d915df9a73861e6ee71ec70bf2339426e7c81a91e5a567273b3b3742d7a99feefd3398d821b26e1ff3a56d0'
+ '527ab66e5eace777de0043c1ca5787a488f6471450ce67fd6d08137ad0ef56177bc0c17696f30a5fca23fa55d8ca9c3f30cb7b17550dba2dbd8e89ca0b361990')
+
+prepare() {
+ cd "$pkgname"
+
+ git submodule init
+ git config submodule."release/scripts/addons".url "${srcdir}/blender-addons"
+ git config submodule."release/scripts/addons_contrib".url "${srcdir}/blender-addons-contrib"
+ git config submodule."release/datafiles/locale".url "${srcdir}/blender-translations"
+ git config submodule."source/tools".url "${srcdir}/blender-dev-tools"
+ git submodule update
+ git submodule foreach git checkout v${pkgver}
+
+ patch -p1 -i "$srcdir"/force-draco1.patch
+ patch -p1 -d release/scripts/addons -i "$srcdir"/force-draco2.patch
+}
+
+build() {
+ cd "$pkgname"
+
+ local PYTHON_VER=3.10
+
+ cmake \
+ -Bbuild \
+ -GNinja \
+ -Cbuild_files/cmake/config/blender_release.cmake \
+ -DOPTIX_ROOT_DIR="$srcdir"/include \
+ -DCMAKE_INSTALL_PREFIX=/usr \
+ -DCMAKE_BUILD_TYPE=Release \
+ -DWITH_INSTALL_PORTABLE=OFF \
+ -DWITH_PYTHON_INSTALL=OFF \
+ -DPYTHON_VERSION=$PYTHON_VER \
+ -DPYTHON_LIBPATH=/usr/lib \
+ -DPYTHON_LIBRARY=python$PYTHON_VER \
+ -DPYTHON_INCLUDE_DIRS=/usr/include/python$PYTHON_VER \
+ -DCMAKE_CXX_FLAGS="-I /usr/include/python$PYTHON_VER"
+ ninja -C build
+}
+
+package() {
+ cd "$pkgname"
+
+ DESTDIR="${pkgdir}" ninja -C build install
+ install -Dm755 release/bin/blender-softwaregl "${pkgdir}/usr/bin/blender-softwaregl"
+ python -m compileall "${pkgdir}/usr/share/blender"
+ python -O -m compileall "${pkgdir}/usr/share/blender"
+
+ install -Dm644 release/freedesktop/org.blender.Blender.appdata.xml "${pkgdir}/usr/share/metainfo/org.blender.Blender.appdata.xml"
+
+ # Manually install additional scripts (See FS#69351)
+ cp -r release/scripts/addons_contrib/* "${pkgdir}"/usr/share/blender/3*/scripts/addons_contrib/
+
+ # Manually install draco bindings (See FS#73415)
+ mkdir -p "${pkgdir}"/usr/lib/python3.10/
+ mv "${pkgdir}"/usr/share/blender/3*/python/lib/* "${pkgdir}"/usr/lib/
+ rm -r "${pkgdir}"/usr/share/blender/3*/python
+}
Copied: blender/repos/community-staging-x86_64/force-draco1.patch (from rev 1207501, blender/trunk/force-draco1.patch)
===================================================================
--- community-staging-x86_64/force-draco1.patch (rev 0)
+++ community-staging-x86_64/force-draco1.patch 2022-05-16 01:11:30 UTC (rev 1207502)
@@ -0,0 +1,15 @@
+diff --git a/CMakeLists.txt b/CMakeLists.txt
+index 75f5795db68..d50686adfb0 100644
+--- a/CMakeLists.txt
++++ b/CMakeLists.txt
+@@ -754,10 +754,6 @@ endif()
+ set_and_warn_dependency(WITH_PYTHON WITH_CYCLES OFF)
+ set_and_warn_dependency(WITH_PYTHON WITH_DRACO OFF)
+
+-if(WITH_DRACO AND NOT WITH_PYTHON_INSTALL)
+- message(STATUS "WITH_DRACO requires WITH_PYTHON_INSTALL to be ON, disabling WITH_DRACO for now")
+- set(WITH_DRACO OFF)
+-endif()
+
+ # enable boost for cycles, audaspace or i18n
+ # otherwise if the user disabled
Copied: blender/repos/community-staging-x86_64/force-draco2.patch (from rev 1207501, blender/trunk/force-draco2.patch)
===================================================================
--- community-staging-x86_64/force-draco2.patch (rev 0)
+++ community-staging-x86_64/force-draco2.patch 2022-05-16 01:11:30 UTC (rev 1207502)
@@ -0,0 +1,21 @@
+diff --git a/io_scene_gltf2/io/com/gltf2_io_draco_compression_extension.py b/io_scene_gltf2/io/com/gltf2_io_draco_compression_extension.py
+index e7518ac4..c0d78564 100644
+--- a/io_scene_gltf2/io/com/gltf2_io_draco_compression_extension.py
++++ b/io_scene_gltf2/io/com/gltf2_io_draco_compression_extension.py
+@@ -13,6 +13,7 @@
+ # limitations under the License.
+
+ import os
++import site
+ import sys
+ from pathlib import Path
+ import bpy
+@@ -30,7 +31,7 @@ def dll_path() -> Path:
+ python_lib = Path('{v[0]}.{v[1]}/python/lib'.format(v=bpy.app.version))
+ python_version = 'python{v[0]}.{v[1]}'.format(v=sys.version_info)
+
+- path = os.environ.get('BLENDER_EXTERN_DRACO_LIBRARY_PATH')
++ path = site.getsitepackages()[0]
+ if path is None:
+ path = {
+ 'win32': blender_root / python_lib / 'site-packages',
More information about the arch-commits
mailing list