[arch-commits] Commit in magma/repos (3 files)

[Sven-Hendrik Haase]

    Date: Monday, May 16, 2022 @ 17:15:42
  Author: svenstaro
Revision: 1207567

archrelease: copy trunk to community-staging-x86_64

Added:
  magma/repos/community-staging-x86_64/
  magma/repos/community-staging-x86_64/PKGBUILD
    (from rev 1207566, magma/trunk/PKGBUILD)
  magma/repos/community-staging-x86_64/add_cuda86_arch.patch
    (from rev 1207566, magma/trunk/add_cuda86_arch.patch)

-----------------------+
 PKGBUILD              |   56 ++++++++++++++++++++++++++++++++++++++++++++++++
 add_cuda86_arch.patch |   19 ++++++++++++++++
 2 files changed, 75 insertions(+)

Copied: magma/repos/community-staging-x86_64/PKGBUILD (from rev 1207566, magma/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-05-16 17:15:42 UTC (rev 1207567)
@@ -0,0 +1,56 @@
+# Maintainer: Sven-Hendrik Haase <svenstaro at archlinux.org>
+# Contributor: bartus <arch-user-repoᘓbartus.33mail.com>
+# Contributor: pingplug <pingplug at foxmail.com>
+# Contributor: cornholio <vigo.the.unholy.carpathian at gmail.com>
+
+pkgname=magma
+pkgver=2.6.2
+pkgrel=2
+pkgdesc="Matrix Algebra on GPU and Multicore Architectures"
+arch=('x86_64')
+url="https://icl.utk.edu/magma/"
+license=('custom')
+depends=('blas' 'lapack' 'cuda')
+makedepends=('gcc11-fortran' 'cmake' 'ninja')
+optdepends=('python: for examples and tests'
+            'gcc11-fortran: Fortran interface')
+source=("${pkgname}-${pkgver}.tar.gz::https://icl.utk.edu/projectsfiles/${pkgname}/downloads/${pkgname}-${pkgver}.tar.gz"
+        'add_cuda86_arch.patch')
+sha256sums=('75b554dab00903e2d10b972c913e50e7f88cbc62f3ae432b5a086c7e4eda0a71'
+            '896a6b66b4e3c10fab9bb3ae27b6783c2fad3ebd5e204d62da9fdec443bd6c15')
+options=(!lto)
+
+prepare() {
+  cd "${pkgname}-${pkgver}"
+
+  patch -Np1 -i "${srcdir}/add_cuda86_arch.patch"
+}
+
+build() {
+  cd "${pkgname}-${pkgver}"
+
+  CC=/usr/bin/gcc-11 \
+  CXX=/usr/bin/g++-11 \
+  FC=/usr/bin/gfortran-11 \
+  cmake \
+    -Bbuild \
+    -GNinja \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DBUILD_SHARED_LIBS=ON \
+    -DGPU_TARGET="sm_52 sm_53 sm_60 sm_61 sm_62 sm_70 sm_72 sm_75 sm_80 sm_86"
+  ninja -C build
+}
+
+package() {
+  cd "${pkgname}-${pkgver}"
+  DESTDIR="${pkgdir}" ninja -Cbuild install
+
+  install -d "${pkgdir}"/usr/share/magma/example
+  cp -r "${srcdir}"/magma-${pkgver}/example/* "${pkgdir}"/usr/share/magma/example/
+  install -d "${pkgdir}"/usr/share/magma/testing
+  cp -r "${srcdir}"/magma-${pkgver}/testing/* "${pkgdir}"/usr/share/magma/testing/
+  install -Dm644 "${srcdir}"/magma-${pkgver}/COPYRIGHT "${pkgdir}"/usr/share/licenses/magma/LICENSE
+}
+
+# vim:set ts=2 sw=2 et:

Copied: magma/repos/community-staging-x86_64/add_cuda86_arch.patch (from rev 1207566, magma/trunk/add_cuda86_arch.patch)
===================================================================
--- community-staging-x86_64/add_cuda86_arch.patch	                        (rev 0)
+++ community-staging-x86_64/add_cuda86_arch.patch	2022-05-16 17:15:42 UTC (rev 1207567)
@@ -0,0 +1,19 @@
+diff --color -aur magma-2.6.1-old/CMakeLists.txt magma-2.6.1-new/CMakeLists.txt
+--- magma-2.6.1-old/CMakeLists.txt      2021-07-13 01:35:20.000000000 +0300
++++ magma-2.6.1-new/CMakeLists.txt      2021-07-21 11:02:28.014236200 +0300
+@@ -294,6 +294,15 @@
+         message( STATUS "    compile for CUDA arch 8.0 (Ampere)" )
+     endif()
+ 
++    if (GPU_TARGET MATCHES sm_86)
++        if (NOT MIN_ARCH)
++            set( MIN_ARCH 860 )
++        endif()
++        set( NV_SM ${NV_SM} -gencode arch=compute_86,code=sm_86 )
++        set( NV_COMP        -gencode arch=compute_86,code=compute_86 )
++        message( STATUS "    compile for CUDA arch 8.6 (Ampere)" )
++    endif()
++
+     if (NOT MIN_ARCH)
+         message( FATAL_ERROR "GPU_TARGET must contain one or more of Fermi, Kepler, Maxwell, Pascal, Volta, Turing, Ampere, or valid sm_[0-9][0-9]" )
+     endif()