[arch-commits] Commit in ninja/repos (2 files)
Anatol Pomozov
anatolik at gemini.archlinux.org
Mon May 16 20:18:30 UTC 2022
Date: Monday, May 16, 2022 @ 20:18:29
Author: anatolik
Revision: 1207602
archrelease: copy trunk to community-testing-x86_64
Added:
ninja/repos/community-testing-x86_64/
ninja/repos/community-testing-x86_64/PKGBUILD
(from rev 1207601, ninja/trunk/PKGBUILD)
----------+
PKGBUILD | 46 ++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 46 insertions(+)
Copied: ninja/repos/community-testing-x86_64/PKGBUILD (from rev 1207601, ninja/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD (rev 0)
+++ community-testing-x86_64/PKGBUILD 2022-05-16 20:18:29 UTC (rev 1207602)
@@ -0,0 +1,46 @@
+# Maintainer: Anatol Pomozov <anatol.pomozov at gmail.com>
+# Contributor: Filip Brcic <brcha at gna.org>
+# Contributor: Mika Fischer <mika.fischer at zoopnet.de>
+# Contributor: Gergely Imreh <imrehgATgmailDOTcom>
+
+pkgname=ninja
+pkgver=1.11.0
+pkgrel=1
+pkgdesc='Small build system with a focus on speed'
+arch=(x86_64)
+url='https://ninja-build.org/'
+license=(Apache)
+depends=(gcc-libs)
+makedepends=(python re2c emacs-nox)
+source=($pkgname-$pkgver.zip::https://github.com/martine/ninja/archive/v$pkgver.zip)
+sha1sums=('e2de757c4dfa38985b348863b43e2609b56ad305')
+
+build() {
+ cd ninja-$pkgver
+
+ python configure.py --bootstrap
+ emacs -Q --batch -f batch-byte-compile misc/ninja-mode.el
+}
+
+check() {
+ cd ninja-$pkgver
+
+ python ./configure.py
+ ./ninja ninja_test
+ ./ninja_test
+}
+
+package() {
+ cd ninja-$pkgver
+
+ install -m755 -D ninja "$pkgdir/usr/bin/ninja"
+ install -m644 -D doc/manual.asciidoc "$pkgdir/usr/share/doc/ninja/manual.asciidoc"
+ install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
+
+ install -m644 -D misc/ninja-mode.el "$pkgdir/usr/share/emacs/site-lisp/ninja-mode.el"
+ install -m644 -D misc/ninja-mode.elc "$pkgdir/usr/share/emacs/site-lisp/ninja-mode.elc"
+ install -m644 -D misc/ninja.vim "$pkgdir/usr/share/vim/vimfiles/syntax/ninja.vim"
+
+ install -m644 -D misc/bash-completion "$pkgdir/usr/share/bash-completion/completions/ninja"
+ install -m644 -D misc/zsh-completion "$pkgdir/usr/share/zsh/site-functions/_ninja"
+}
More information about the arch-commits
mailing list