[arch-commits] Commit in netcdf-openmpi/repos (2 files)

[Bruno Pagani]

    Date: Wednesday, May 18, 2022 @ 21:44:58
  Author: archange
Revision: 1209163

archrelease: copy trunk to community-staging-x86_64

Added:
  netcdf-openmpi/repos/community-staging-x86_64/
  netcdf-openmpi/repos/community-staging-x86_64/PKGBUILD
    (from rev 1209162, netcdf-openmpi/trunk/PKGBUILD)

----------+
 PKGBUILD |   61 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 61 insertions(+)

Copied: netcdf-openmpi/repos/community-staging-x86_64/PKGBUILD (from rev 1209162, netcdf-openmpi/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-05-18 21:44:58 UTC (rev 1209163)
@@ -0,0 +1,61 @@
+# Maintainer: Ronald van Haren <ronald.archlinux.org>
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+# Contributor: damir <damir at archlinux.org>
+
+_pkg=netcdf
+_mpi=openmpi
+pkgname=${_pkg}-${_mpi}
+pkgver=4.8.1
+pkgrel=3
+pkgdesc="network Common Data Form interface for array-oriented data access and corresponding library with parallel support (${_mpi} version)"
+arch=(x86_64)
+url="https://www.unidata.ucar.edu/software/netcdf/"
+license=(custom)
+depends=("hdf5-${_mpi}" "pnetcdf-${_mpi}" curl)
+makedepends=(cmake)
+optdepends=('netcdf-fortran: fortran bindings' 'netcdf-cxx: c++ bindings')
+checkdepends=(inetutils unzip)
+provides=("${_pkg}")
+conflicts=("${_pkg}")
+options=(!makeflags)
+source=(https://github.com/Unidata/netcdf-c/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz)
+sha256sums=('bc018cc30d5da402622bf76462480664c6668b55eb16ba205a0dfb8647161dd0')
+
+prepare() {
+  # https://github.com/Unidata/netcdf-c/issues/2242
+  sed -i "/add_sh_test(ncdap tst_remote3)/d" ${_pkg}-c-${pkgver}/ncdap_test/CMakeLists.txt
+}
+
+build() {
+  export CC=mpicc
+  # Disabling remote tests because of https://github.com/Unidata/netcdf-c/issues/2188
+  cmake -B build -S ${_pkg}-c-${pkgver} \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=lib \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DENABLE_BYTERANGE=ON \
+    -DENABLE_CDF5=ON \
+    -DENABLE_PNETCDF=ON \
+    -DENABLE_DAP_LONG_TESTS=OFF \
+    -DENABLE_DAP_REMOTE_TESTS=OFF \
+    -DENABLE_EXAMPLE_TESTS=ON \
+    -DENABLE_EXTRA_TESTS=ON \
+    -DENABLE_FILTER_TESTING=ON \
+    -DENABLE_LARGE_FILE_TESTS=ON \
+    -DENABLE_UNIT_TESTS=ON
+  make -C build
+}
+
+
+check() {
+  # This is required starting with OpenMPI 3.0 when trying to run more
+  # processes than the number of available cores
+  export OMPI_MCA_rmaps_base_oversubscribe=yes
+
+  make -C build test
+}
+
+package() {
+  make -C build DESTDIR="${pkgdir}" install
+  install -Dm644 ${_pkg}-c-${pkgver}/COPYRIGHT -t "${pkgdir}"/usr/share/licenses/${_pkg}/
+}