[arch-commits] Commit in (4 files)

[Kpcyrd]

    Date: Wednesday, May 18, 2022 @ 22:50:44
  Author: kpcyrd
Revision: 1209192

addpkg: spotify-launcher 0.2.0-1

Added:
  spotify-launcher/
  spotify-launcher/repos/
  spotify-launcher/trunk/
  spotify-launcher/trunk/PKGBUILD

----------+
 PKGBUILD |   51 +++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

Added: spotify-launcher/trunk/PKGBUILD
===================================================================
--- spotify-launcher/trunk/PKGBUILD	                        (rev 0)
+++ spotify-launcher/trunk/PKGBUILD	2022-05-18 22:50:44 UTC (rev 1209192)
@@ -0,0 +1,51 @@
+# Maintainer: kpcyrd <kpcyrd[at]archlinux[dot]org>
+
+pkgname=spotify-launcher
+pkgver=0.2.0
+pkgrel=1
+pkgdesc="Client for spotify's apt repository in Rust for Arch Linux"
+url='https://github.com/kpcyrd/spotify-launcher'
+arch=('x86_64')
+license=('MIT' 'Apache')
+depends=('sequoia-sqv' 'zenity' 'alsa-lib>=1.0.14' 'gtk3' 'libxss' 'desktop-file-utils' 'openssl' 'nss' 'at-spi2-atk' 'libcurl-gnutls' 'libsm')
+makedepends=('cargo')
+source=(https://github.com/kpcyrd/${pkgname}/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz
+        https://github.com/kpcyrd/${pkgname}/releases/download/v${pkgver}/${pkgname}-${pkgver}.tar.gz.asc)
+b2sums=('2139a0c08a6d5edd8eaee3b806b7ae786e8754d49715f22f6f5962f7b8b6308938d294c807297165c4ee2295d2380612e9f094cc871eabcf9f3f9e06ff14f703'
+        'SKIP')
+options=('!lto')
+
+validpgpkeys=("64B13F7117D6E07D661BBCE0FE763A64F5E54FD6")
+
+prepare() {
+  cd "${pkgname}-${pkgver}"
+  cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
+}
+
+build() {
+  cd "${pkgname}-${pkgver}"
+  cargo build --frozen --release
+}
+
+check() {
+  cd "${pkgname}-${pkgver}"
+  cargo test --frozen
+}
+
+package() {
+  cd "${pkgname}-${pkgver}"
+  install -Dm 755 -t "${pkgdir}/usr/bin" \
+    target/release/spotify-launcher
+  install -Dm 644 data/pubkey_5E3C45D7B312C643.gpg \
+    "${pkgdir}/usr/share/spotify-launcher/keyring.pgp"
+
+  install -Dm644 contrib/spotify-launcher.desktop -t "${pkgdir}/usr/share/applications"
+  install -Dm644 contrib/icons/spotify-linux-512.png "${pkgdir}/usr/share/pixmaps/spotify-launcher.png"
+
+  for size in 22 24 32 48 64 128 256 512; do
+    install -Dm644 "contrib/icons/spotify-linux-${size}.png" \
+      "${pkgdir}/usr/share/icons/hicolor/${size}x${size}/apps/spotify-launcher.png"
+  done
+}
+
+# vim: ts=2 sw=2 et: