[arch-commits] Commit in plasma-workspace/repos (3 files)

Antonio Rojas arojas at gemini.archlinux.org
Thu May 19 17:45:33 UTC 2022


    Date: Thursday, May 19, 2022 @ 17:45:32
  Author: arojas
Revision: 446060

archrelease: copy kde-unstable to kde-unstable-x86_64

Added:
  plasma-workspace/repos/kde-unstable-x86_64/
  plasma-workspace/repos/kde-unstable-x86_64/PKGBUILD
    (from rev 446059, plasma-workspace/kde-unstable/PKGBUILD)
  plasma-workspace/repos/kde-unstable-x86_64/kde.pam
    (from rev 446059, plasma-workspace/kde-unstable/kde.pam)

----------+
 PKGBUILD |   59 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 kde.pam  |    9 +++++++++
 2 files changed, 68 insertions(+)

Copied: plasma-workspace/repos/kde-unstable-x86_64/PKGBUILD (from rev 446059, plasma-workspace/kde-unstable/PKGBUILD)
===================================================================
--- kde-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ kde-unstable-x86_64/PKGBUILD	2022-05-19 17:45:32 UTC (rev 446060)
@@ -0,0 +1,59 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+# Contributor: Alexey D. <lq07829icatm at rambler.ru>
+
+pkgbase=plasma-workspace
+pkgname=(plasma-workspace plasma-wayland-session)
+pkgver=5.24.90
+pkgrel=1
+pkgdesc='KDE Plasma Workspace'
+arch=(x86_64)
+url='https://kde.org/plasma-desktop/'
+license=(LGPL)
+depends=(knotifyconfig ksystemstats ktexteditor libqalculate kde-cli-tools appstream-qt
+         xorg-xrdb xorg-xsetroot kactivitymanagerd kholidays xorg-xmessage milou prison kwin
+         plasma-integration kpeople kactivities-stats libkscreen kquickcharts kuserfeedback
+         accountsservice kio-extras kio-fuse qt5-tools)
+makedepends=(extra-cmake-modules kdoctools gpsd baloo networkmanager-qt plasma-wayland-protocols kunitconversion kinit)
+groups=(plasma)
+source=(https://download.kde.org/unstable/plasma/$pkgver/$pkgbase-$pkgver.tar.xz{,.sig} kde.pam)
+sha256sums=('71f21366c20768f0eceab3a0e2e6dee3ec470b7dd8645fd41550ce4eec0246d9'
+            'SKIP'
+            '00090291204baabe9d6857d3b1419832376dd2e279087d718b64792691e86739')
+validpgpkeys=('E0A3EB202F8E57528E13E72FD7574483BB57B18D'  # Jonathan Esk-Riddell <jr at jriddell.org>
+              '0AAC775BB6437A8D9AF7A3ACFE0784117FBCE11D'  # Bhushan Shah <bshah at kde.org>
+              'D07BD8662C56CB291B316EB2F5675605C74E02CF'  # David Edmundson <davidedmundson at kde.org>
+              '1FA881591C26B276D7A5518EEAAF29B42A678C20') # Marco Martin <notmart at gmail.com>
+options=(debug)
+
+build() {
+  cmake -B build -S $pkgbase-$pkgver \
+    -DCMAKE_INSTALL_LIBEXECDIR=lib \
+    -DBUILD_TESTING=OFF
+  cmake --build build
+}
+
+package_plasma-workspace() {
+  optdepends=('plasma-workspace-wallpapers: additional wallpapers'
+              'gpsd: GPS based geolocation' 'networkmanager-qt: IP based geolocation'
+              'kdepim-addons: displaying PIM events in the calendar'
+              'appmenu-gtk-module: global menu support for GTK2 and some GTK3 applications'
+              'baloo: Baloo search runner' 'discover: manage applications installation from the launcher')
+  backup=('etc/pam.d/kde')
+
+  DESTDIR="$pkgdir" cmake --install build
+
+  install -Dm644 "$srcdir"/kde.pam "$pkgdir"/etc/pam.d/kde
+
+  # Split plasma-wayland scripts
+  rm -r "$pkgdir"/usr/share/wayland-sessions
+}
+
+package_plasma-wayland-session() {
+  pkgdesc='Plasma Wayland session'
+  depends=(plasma-workspace qt5-wayland kwayland-integration xorg-xwayland)
+  groups=()
+
+  install -Dm644 build/login-sessions/plasmawayland.desktop "$pkgdir"/usr/share/wayland-sessions/plasmawayland.desktop
+}

Copied: plasma-workspace/repos/kde-unstable-x86_64/kde.pam (from rev 446059, plasma-workspace/kde-unstable/kde.pam)
===================================================================
--- kde-unstable-x86_64/kde.pam	                        (rev 0)
+++ kde-unstable-x86_64/kde.pam	2022-05-19 17:45:32 UTC (rev 446060)
@@ -0,0 +1,9 @@
+#%PAM-1.0
+
+auth            include         system-login
+
+account         include         system-login
+
+password        include         system-login
+
+session         include         system-login



More information about the arch-commits mailing list