[arch-commits] Commit in libxkbcommon/repos/extra-x86_64 (PKGBUILD PKGBUILD)
Jan Steffens
heftig at gemini.archlinux.org
Sat May 21 22:30:04 UTC 2022
Date: Saturday, May 21, 2022 @ 22:30:04
Author: heftig
Revision: 446413
archrelease: copy trunk to extra-x86_64
Added:
libxkbcommon/repos/extra-x86_64/PKGBUILD
(from rev 446412, libxkbcommon/trunk/PKGBUILD)
Deleted:
libxkbcommon/repos/extra-x86_64/PKGBUILD
----------+
PKGBUILD | 198 ++++++++++++++++++++++++++++++++++++-------------------------
1 file changed, 118 insertions(+), 80 deletions(-)
Deleted: PKGBUILD
===================================================================
--- PKGBUILD 2022-05-21 22:28:12 UTC (rev 446412)
+++ PKGBUILD 2022-05-21 22:30:04 UTC (rev 446413)
@@ -1,80 +0,0 @@
-# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
-# Contributor: Daniel Micay <danielmicay at gmail.com>
-# Contributor: Mladen Pejakovic <pejakm at gmail.com>
-
-pkgbase=libxkbcommon
-pkgname=(libxkbcommon libxkbcommon-doc libxkbcommon-x11)
-pkgver=1.4.0
-pkgrel=1
-pkgdesc="Keymap handling library for toolkits and window systems"
-url="https://xkbcommon.org/"
-arch=(x86_64)
-license=(custom)
-makedepends=(xkeyboard-config libxml2 libxcb wayland wayland-protocols doxygen
- git meson xorgproto)
-checkdepends=(xorg-server-xvfb libgl)
-_commit=ea6580cc3913d93655ecf92a5913de652315efc3 # tags/xkbcommon-1.4.0^0
-source=("git+https://github.com/xkbcommon/libxkbcommon#commit=$_commit")
-sha256sums=('SKIP')
-
-pkgver() {
- cd $pkgbase
- git describe --tags | sed 's/^xkbcommon-//;s/-/+/g'
-}
-
-prepare() {
- cd $pkgbase
-}
-
-build() {
- arch-meson $pkgbase build
- meson compile -C build
-}
-
-check() {
- xvfb-run -s '-nolisten local' meson test -C build --print-errorlogs
-}
-
-_pick() {
- local p="$1" f d; shift
- for f; do
- d="$srcdir/$p/${f#$pkgdir/}"
- mkdir -p "$(dirname "$d")"
- mv "$f" "$d"
- rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
- done
-}
-
-package_libxkbcommon() {
- depends=(xkeyboard-config libxml2)
- optdepends=('libxkbcommon-x11: xkbcli interactive-x11'
- 'wayland: xkbcli interactive-wayland')
- provides=(libxkbcommon.so libxkbregistry.so)
-
- meson install -C build --destdir "$pkgdir"
- install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 $pkgbase/LICENSE
-
- _pick libxkbcommon-doc "$pkgdir"/usr/share/doc
-
- _pick libxkbcommon-x11 "$pkgdir"/usr/lib/*x11*
- _pick libxkbcommon-x11 "$pkgdir"/usr/lib/pkgconfig/*x11*
- _pick libxkbcommon-x11 "$pkgdir"/usr/lib/xkbcommon/*x11*
- _pick libxkbcommon-x11 "$pkgdir"/usr/include/xkbcommon/*x11*
- _pick libxkbcommon-x11 "$pkgdir"/usr/share/man/man1/*x11*
-}
-
-package_libxkbcommon-doc() {
- pkgdesc="API documentation for libxkbcommon"
-
- mv libxkbcommon-doc/* "$pkgdir"
- install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 $pkgbase/LICENSE
-}
-
-package_libxkbcommon-x11() {
- pkgdesc="Keyboard handling library using XKB data for X11 XCB clients"
- depends=(libxkbcommon libxkbcommon.so libxcb)
- provides=(libxkbcommon-x11.so)
-
- mv libxkbcommon-x11/* "$pkgdir"
- install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 $pkgbase/LICENSE
-}
Copied: libxkbcommon/repos/extra-x86_64/PKGBUILD (from rev 446412, libxkbcommon/trunk/PKGBUILD)
===================================================================
--- PKGBUILD (rev 0)
+++ PKGBUILD 2022-05-21 22:30:04 UTC (rev 446413)
@@ -0,0 +1,118 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Daniel Micay <danielmicay at gmail.com>
+# Contributor: Mladen Pejakovic <pejakm at gmail.com>
+
+pkgbase=libxkbcommon
+pkgname=(
+ libxkbcommon
+ libxkbcommon-x11
+ libxkbcommon-doc
+)
+pkgver=1.4.1
+pkgrel=1
+pkgdesc='Keymap handling library for toolkits and window systems'
+url='https://xkbcommon.org/'
+arch=(x86_64)
+license=(custom)
+makedepends=(
+ doxygen
+ git
+ libxcb
+ libxml2
+ meson
+ wayland
+ wayland-protocols
+ xkeyboard-config
+ xorgproto
+)
+checkdepends=(
+ libgl
+ xorg-server-xvfb
+)
+options=(
+ debug
+)
+_commit=57af9cb71f19f37394399b549f7cb7b0d9fe3988 # tags/xkbcommon-1.4.1^0
+source=("git+https://github.com/xkbcommon/libxkbcommon#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+ cd libxkbcommon
+ git describe --tags | sed 's/^xkbcommon-//;s/[^-]*-g/r&/;s/-/+/g'
+}
+
+prepare() {
+ cd libxkbcommon
+}
+
+build() {
+ arch-meson libxkbcommon build
+ meson compile -C build
+}
+
+check() {
+ xvfb-run -s '-nolisten local' meson test -C build --print-errorlogs
+}
+
+_pick() {
+ local p="$1" f d; shift
+ for f; do
+ d="$srcdir/$p/${f#$pkgdir/}"
+ mkdir -p "$(dirname "$d")"
+ mv "$f" "$d"
+ rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
+ done
+}
+
+package_libxkbcommon() {
+ depends=(
+ libxml2
+ xkeyboard-config
+ )
+ optdepends=(
+ 'libxkbcommon-x11: xkbcli interactive-x11'
+ 'wayland: xkbcli interactive-wayland'
+ )
+ provides=(
+ libxkbcommon.so
+ libxkbregistry.so
+ )
+
+ meson install -C build --destdir "$pkgdir"
+
+ _pick x11 "$pkgdir"/usr/lib/*x11*
+ _pick x11 "$pkgdir"/usr/lib/pkgconfig/*x11*
+ _pick x11 "$pkgdir"/usr/lib/xkbcommon/*x11*
+ _pick x11 "$pkgdir"/usr/include/xkbcommon/*x11*
+ _pick x11 "$pkgdir"/usr/share/man/man1/*x11*
+
+ _pick doc "$pkgdir"/usr/share/doc
+
+ install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 libxkbcommon/LICENSE
+}
+
+package_libxkbcommon-x11() {
+ pkgdesc='Keyboard handling library using XKB data for X11 XCB clients'
+ depends=(
+ libxcb
+ libxkbcommon
+ libxkbcommon.so
+ )
+ provides=(
+ libxkbcommon-x11.so
+ )
+
+ mv x11/* "$pkgdir"/
+
+ install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 libxkbcommon/LICENSE
+}
+
+package_libxkbcommon-doc() {
+ pkgdesc='API documentation for libxkbcommon'
+
+ mv doc/* "$pkgdir"/
+
+ install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 libxkbcommon/LICENSE
+}
+
+# vim:set sw=2 sts=-1 et:
More information about the arch-commits
mailing list