[arch-commits] Commit in (3 files)

[Maxime Gauduin]

    Date: Monday, May 23, 2022 @ 12:55:40
  Author: alucryd
Revision: 1210103

add crosstool-ng

Added:
  crosstool-ng/
  crosstool-ng/trunk/
  crosstool-ng/trunk/PKGBUILD

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Added: crosstool-ng/trunk/PKGBUILD
===================================================================
--- crosstool-ng/trunk/PKGBUILD	                        (rev 0)
+++ crosstool-ng/trunk/PKGBUILD	2022-05-23 12:55:40 UTC (rev 1210103)
@@ -0,0 +1,47 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: Christian Pfeiffer <cpfeiffer at live dot de>
+# Contributor: Bartłomiej Piotrowski <bpiotrowski at archlinux.org>
+# Contributor: jwwolf <jwwolf+arch at gmail.com>
+# Contributor: Bernhard Walle <bernhard at bwalle.de>
+
+pkgname=crosstool-ng
+pkgver=1.25.0
+pkgrel=1
+pkgdesc='A versatile (cross-)toolchain generator'
+arch=(x86_64)
+url=https://crosstool-ng.github.io/
+license=(GPL2)
+depends=(
+  git
+  gperf
+  help2man
+  lzip
+  ncurses
+  python
+  unzip
+)
+_tag=8fa98eeeff9bc53478d97ef722f366fea151ae64
+source=(git+https://github.com/crosstool-ng/crosstool-ng.git#tag=${_tag})
+b2sums=(SKIP)
+
+prepare() {
+  cd crosstool-ng
+  ./bootstrap
+}
+
+build() {
+  cd crosstool-ng
+  ./configure \
+    --prefix=/usr \
+    --libexecdir=/usr/lib \
+    --with-bash-completion \
+    --with-ncurses
+  make
+}
+
+package() {
+  cd crosstool-ng
+  make DESTDIR="${pkgdir}" install
+}
+
+# vim: ts=2 sw=2 et: