[arch-commits] Commit in python-jinja/repos (2 files)

[Evangelos Foutras]

    Date: Tuesday, May 24, 2022 @ 13:36:49
  Author: foutrelis
Revision: 1210210

archrelease: copy trunk to community-testing-any

Added:
  python-jinja/repos/community-testing-any/
  python-jinja/repos/community-testing-any/PKGBUILD
    (from rev 1210209, python-jinja/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: python-jinja/repos/community-testing-any/PKGBUILD (from rev 1210209, python-jinja/trunk/PKGBUILD)
===================================================================
--- community-testing-any/PKGBUILD	                        (rev 0)
+++ community-testing-any/PKGBUILD	2022-05-24 13:36:49 UTC (rev 1210210)
@@ -0,0 +1,44 @@
+# Maintainer: Evangelos Foutras <evangelos at foutrelis.com>
+# Contributor: David Runge <dave at sleepmap.de>
+# Contributor: Peter Baldwin <bald_pete at hotmail.com>
+
+pkgname=python-jinja
+pkgver=3.1.2
+pkgrel=1
+epoch=1
+pkgdesc="A simple pythonic template language written in Python"
+arch=('any')
+url="https://palletsprojects.com/p/jinja/"
+license=('BSD')
+depends=('python-markupsafe')
+makedepends=('python-setuptools')
+optdepends=('python-babel: for i18n support')
+checkdepends=('python-pytest')
+source=(https://files.pythonhosted.org/packages/source/J/Jinja2/Jinja2-$pkgver.tar.gz)
+sha256sums=('31351a702a408a9e7595a8fc6150fc3f43bb6bf7e319770cbc0db9df9437e852')
+
+build() {
+  cd Jinja2-$pkgver
+  python3 setup.py build
+}
+
+check() {
+  cd Jinja2-$pkgver
+  # https://github.com/pypa/setuptools/issues/2466
+  PYTHONPATH=build/lib pytest \
+    --deselect tests/test_loader.py::test_package_dir_list \
+    --deselect tests/test_loader.py::test_package_dir_source \
+    --deselect tests/test_loader.py::test_package_file_list \
+    --deselect tests/test_loader.py::test_package_file_source \
+    --deselect tests/test_loader.py::test_package_zip_list \
+    --deselect tests/test_loader.py::test_package_zip_omit_curdir \
+    --deselect tests/test_loader.py::test_package_zip_source
+}
+
+package() {
+  cd Jinja2-$pkgver
+  python3 setup.py install --root="$pkgdir" --optimize=1 --skip-build
+  install -Dm644 LICENSE.rst -t "$pkgdir/usr/share/licenses/$pkgname"
+}
+
+# vim:set ts=2 sw=2 et: