[arch-commits] Commit in (cl-cffi cl-cffi/repos cl-cffi/trunk cl-cffi/trunk/PKGBUILD)
George Rawlinson
grawlinson at gemini.archlinux.org
Wed May 25 02:49:55 UTC 2022
Date: Wednesday, May 25, 2022 @ 02:49:54
Author: grawlinson
Revision: 1210304
addpkg: cl-cffi 0.24.1.r19-3
Added:
cl-cffi/
cl-cffi/repos/
cl-cffi/trunk/
cl-cffi/trunk/PKGBUILD
----------+
PKGBUILD | 66 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 66 insertions(+)
Added: cl-cffi/trunk/PKGBUILD
===================================================================
--- cl-cffi/trunk/PKGBUILD (rev 0)
+++ cl-cffi/trunk/PKGBUILD 2022-05-25 02:49:54 UTC (rev 1210304)
@@ -0,0 +1,66 @@
+# Maintainer: George Rawlinson <grawlinson at archlinux.org>
+
+pkgname=cl-cffi
+_pkgname="${pkgname#cl-}"
+pkgver=0.24.1.r19.g3c76afe
+pkgrel=3
+pkgdesc='Common Foreign Function Interface for Common Lisp'
+arch=('any')
+url='https://cffi.common-lisp.dev/'
+license=('MIT')
+depends=(
+ 'common-lisp'
+ 'cl-asdf'
+ 'cl-babel'
+ 'cl-alexandria'
+ 'cl-trivial-features'
+ 'cl-ppcre'
+ 'cl-json'
+ 'libffi'
+)
+makedepends=('git')
+checkdepends=('sbcl' 'cl-bordeaux-threads' 'cl-rt')
+_commit='3c76afe7ba03ce015e0df99ac9ddcd61320a44a4'
+source=("$pkgname::git+https://github.com/cffi/cffi#commit=$_commit")
+b2sums=('SKIP')
+
+pkgver() {
+ cd "$pkgname"
+
+ git describe --tags | sed -e 's/^v//' -e 's/-/.r/' -e 's/-/./g'
+}
+
+prepare() {
+ cd "$pkgname"
+
+ # add local dir so asdf can pick up library
+ sed \
+ -i tests/run-tests.lisp \
+ -e '/(require "asdf")/a (push (uiop/os:getcwd) asdf:*central-registry*)'
+}
+
+check() {
+ cd "$pkgname"
+
+ sbcl --script tests/run-tests.lisp
+
+ # delete test artifacts
+ find . -name '*.o' -delete -or -name '*.so' -delete
+}
+
+package() {
+ cd "$pkgname"
+
+ # library
+ install -vd "$pkgdir/usr/share/common-lisp/source/$_pkgname"
+ cp -vr \
+ examples grovel libffi src tests toolchain uffi-compat \
+ ./*.asd \
+ "$pkgdir/usr/share/common-lisp/source/$_pkgname"
+
+ # documentation
+ install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" README.md
+
+ # license
+ install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" COPYRIGHT
+}
More information about the arch-commits
mailing list