[arch-commits] Commit in (4 files)

[George Rawlinson]

    Date: Wednesday, May 25, 2022 @ 07:56:55
  Author: grawlinson
Revision: 1210327

addpkg: check-sieve 0.8-1

Added:
  check-sieve/
  check-sieve/repos/
  check-sieve/trunk/
  check-sieve/trunk/PKGBUILD

----------+
 PKGBUILD |   59 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)

Added: check-sieve/trunk/PKGBUILD
===================================================================
--- check-sieve/trunk/PKGBUILD	                        (rev 0)
+++ check-sieve/trunk/PKGBUILD	2022-05-25 07:56:55 UTC (rev 1210327)
@@ -0,0 +1,59 @@
+# Maintainer: George Rawlinson <grawlinson at archlinux.org>
+# Contributor: Geoffrey Frogeye <geoffrey+aur at frogeye.fr>
+
+pkgname=check-sieve
+pkgver=0.8
+pkgrel=1
+pkgdesc='Syntax checker for Sieve scripts'
+arch=('x86_64')
+url='https://github.com/dburkart/check-sieve'
+license=('MIT')
+depends=('gcc-libs')
+makedepends=('git')
+checkdepends=('python')
+_commit='18bb1f9ac8b233ac29f94212f94148b7855af714'
+source=("$pkgname::git+$url#commit=$_commit")
+b2sums=('SKIP')
+
+pkgver() {
+  cd "$pkgname"
+
+  git describe --tags | sed 's/^check-sieve-//'
+}
+
+prepare() {
+  cd "$pkgname"
+
+  # ensure LDFLAGS are passed to compiler
+  sed \
+    -i Makefile \
+    -e '/\t$(CXX).*/s/$/ $(LDFLAGS)/'
+}
+
+
+build() {
+  cd "$pkgname"
+
+  export CFLAGS+=" -ffat-lto-objects"
+
+  make
+}
+
+check() {
+  cd "$pkgname"
+
+  make test
+}
+
+package() {
+  cd "$pkgname"
+
+  make INSTALL_PREFIX="$pkgdir/usr" install
+
+  # license
+  install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
+
+  # fix incorrect permissions on library
+  chmod 644 "$pkgdir/usr/lib/libchecksieve.a"
+}
+